Linh kiện

Cảm biến chất lượng không khí CCS811

Con CCS811 của ams trên bo mạch CJMCU-811 báo CO2 tương đương (eCO2) và TVOC qua I2C tại 0x5A.

This part has a page of its own, with a note on using it and a circuit to try: the part page.

Tên gọi khác: CJMCU-811, CCS811 breakout, Adafruit CCS811, SparkFun CCS811, cảm biến eCO2, cảm biến TVOC. Một cảm biến khí kim loại ô-xít tí hon có vi điều khiển riêng bên trong. Nó nung nóng một lớp cảm biến, theo dõi điện trở thay đổi khi các hợp chất hữu cơ bay hơi (VOC) đi qua, và tính ra hai con số: TVOC, tổng VOC tính theo phần tỷ, và eCO2, mức carbon dioxide tính theo phần triệu mà người thở ra sẽ tạo ra cùng với chúng. Nó không đo trực tiếp CO2: muốn vậy bạn cần cảm biến NDIR như SCD40.

Pins

Pin Công dụng
VCC Nguồn cấp 3,3 V. Con chip chạy từ 1,8 đến 3,6 V và bo mạch này không có bộ ổn áp.
GND Nguồn cấp.
SCL, SDA I2C. Bo mạch có sẵn điện trở kéo lên.
WAK nWAKE, tác động mức thấp. Con chip chỉ lắng nghe khi chân này ở mức thấp: nối nó vào GND, hoặc vào một chân bạn giữ mức thấp khi giao tiếp. Nếu không nối dây, sẽ không có gì trả lời.
INT nINT, một ngõ xuất open-drain kéo xuống mức thấp khi có mẫu sẵn sàng (hoặc vượt ngưỡng), nếu sketch yêu cầu.
RST nRESET, tác động mức thấp; được kéo lên bên trong chip, nên có thể để không nối.
ADD Địa chỉ: mức thấp (điện trở kéo xuống của bo mạch) là 0x5A, mức cao là 0x5B.

Thuộc tính

eco2 (ppm, 400 đến 8192) và tvoc (ppb, 0 đến 1187) là không khí, dải xuất của con chip. Hai thanh trượt thay đổi chúng khi mạch đang chạy, và mẫu kế tiếp sẽ báo các giá trị đó.

Đọc nó trên Arduino

Với thư viện của Adafruit, mà Mokxi kèm sẵn dưới dạng Adafruit_CCS811.h:

#include <Wire.h>
#include "Adafruit_CCS811.h"

Adafruit_CCS811 ccs;

void setup() {
  Serial.begin(9600);
  if (!ccs.begin()) {           // 0x5A; begin(0x5B) with ADD high
    Serial.println("No CCS811");
    while (1) {}
  }
  while (!ccs.available()) {}   // the first sample, a second later
}

void loop() {
  if (ccs.available() && ccs.readData() == 0) {
    Serial.print(ccs.geteCO2());
    Serial.print(" ppm eCO2, ");
    Serial.print(ccs.getTVOC());
    Serial.println(" ppb TVOC");
  }
  delay(250);
}

readData() trả về 0 khi thành công. Ví dụ CCS811 air quality trong thư viện in cả hai giá trị mỗi giây.

Cách nó giao tiếp

  • Sau khi cấp nguồn, chip trả lời trong 20 ms, ở chế độ boot: STATUS (0x00) đọc được 0x10 (một ứng dụng hợp lệ đã được nạp) và HW_ID (0x20) đọc được 0x81.
  • Ghi địa chỉ thanh ghi 0xF4 (APP_START) và không gì khác sẽ khởi động ứng dụng: STATUS có thêm bit FW_MODE và đọc được 0x90.
  • MEAS_MODE (0x01) chọn chế độ hoạt động: 0 nghỉ, 1 một mẫu mỗi giây, 2 mỗi 10 s, 3 mỗi 60 s, 4 dữ liệu thô mỗi 250 ms. Bit 3 yêu cầu nINT ở mỗi mẫu, còn bit 2 chỉ khi eCO2 chuyển sang một khoảng khác đặt trong THRESHOLDS (0x10).
  • Ở mỗi mẫu, DATA_READY (bit 3 của STATUS) được đặt. ALG_RESULT_DATA (0x02) gồm tám byte: eCO2 và TVOC, byte cao trước, rồi STATUS, ERROR_ID và dữ liệu thô. Đọc nó sẽ xóa DATA_READY và thả nINT.
  • Các thanh ghi giống hộp thư: địa chỉ không tự tăng, nên một lần đọc liên tục lấy được các byte của một thanh ghi theo đúng thứ tự.
  • ENV_DATA (0x05) nhận độ ẩm và nhiệt độ để bù trừ, BASELINE (0x11) lưu và khôi phục đường cơ sở, còn SW_RESET (0xFF với 11 E5 72 8A) quay về chế độ boot.
  • Một thanh ghi sai, hay chế độ hoạt động trên 4, sẽ đặt ERROR trong STATUS và một bit trong ERROR_ID (0xE0).

Những gì nó không mô phỏng

Hóa học của khí. Các số đo là các thanh trượt, mẫu này đến mẫu khác; 48 giờ chạy rà, 20 phút khởi động, việc tự hiệu chỉnh đường cơ sở và bù nhiệt độ, độ ẩm không được mô phỏng (ENV_DATA và BASELINE giữ nguyên giá trị được ghi). RAW_DATA là giá trị thay thế cố định, NTC đọc bằng không, các lỗi bộ gia nhiệt, việc tải firmware và mười phút nghỉ mà tài liệu yêu cầu trước khi chuyển sang chế độ chậm hơn không được kiểm tra. Điện áp quá cao trên VCC không gây hư hại gì ở đây.

Common mistakes

Để WAK không nối dây: chip bỏ qua bus cho đến khi nWAKE ở mức thấp. Cấp nguồn 5 V: CJMCU-811 không có ổn áp, còn giới hạn của chip là 3.6 V. Đọc liên tục hết tốc độ vòng lặp: chế độ 1 chỉ có mẫu mới mỗi giây một lần, nên hãy chờ available(). Tin các số đo đầu tiên trên cảm biến thật: nó cần 20 phút để ổn định, và 48 giờ khi còn mới.