Plant monitor: light, soil, temperature and a pump, on an Arduino Uno

// A plant monitor: three sensors, a display, and a pump for dry soil.
//
//   photoresistor from A0 -> GND, 10k from 5V -> A0
//   soil moisture sensor AOUT -> A1   VCC -> 5V   GND -> GND
//   thermistor from 5V -> A2, 10k from A2 -> GND
//   L293D 1,2EN, VCC1, VCC2 -> 5V   GND -> GND   1A -> pin 12
//   1Y -> the pump's + lead; the pump's - lead -> GND
//   I2C LCD GND -> GND   VCC -> 5V   SDA -> A4   SCL -> A5
//
// The display takes turns: temperature, then light and soil. A capacitive
// soil sensor reads lower when the soil is wetter, so a reading above DRY
// means the plant needs water, and the pump runs for a second.
//
// Drag the soil sensor towards dry.

#include <Wire.h>
#include <LiquidCrystal_I2C.h>

const int LIGHT = A0;
const int SOIL = A1;
const int TEMP = A2;
const int PUMP = 12;
const int DRY = 500;
const float SERIES_OHMS = 10000.0;

LiquidCrystal_I2C lcd(0x27, 16, 2);

// The thermistor is the top of this divider, so a warmer bead reads higher.
float celsius(int reading) {
  float r = SERIES_OHMS * (1023.0 - reading) / reading;
  float kelvin = 1.0 / (1.0 / (25.0 + 273.15) + log(r / 10000.0) / 3950.0);
  return kelvin - 273.15;
}

void setup() {
  pinMode(PUMP, OUTPUT);
  digitalWrite(PUMP, LOW);
  lcd.init();
  lcd.backlight();
  Serial.begin(9600);
  Serial.println("Mokxi Uno: plant monitor");
}

void loop() {
  float c = celsius(analogRead(TEMP));
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Temp C: ");
  lcd.print(c);
  lcd.setCursor(0, 1);
  lcd.print("Temp F: ");
  lcd.print(c * 9.0 / 5.0 + 32.0);
  delay(1500);

  int light = analogRead(LIGHT);
  int soil = analogRead(SOIL);
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Light: ");
  lcd.print(light);
  lcd.setCursor(0, 1);
  lcd.print("Soil: ");
  lcd.print(soil);
  Serial.print("light ");
  Serial.print(light);
  Serial.print("  soil ");
  Serial.print(soil);
  Serial.print("  temp ");
  Serial.println(c);
  if (soil > DRY) {
    Serial.println("dry soil: watering");
    digitalWrite(PUMP, HIGH);
    delay(1000);
    digitalWrite(PUMP, LOW);
  }
  delay(1500);
}