ESP32 WiFi, HTTPClient and WebServer: the core libraries for networking

/*
 * WiFi: a lamp on a web page.
 *
 * The server is your code, running on the board's core. The NETWORK under it is
 * SIMULATED: there is no 802.11, no TCP and no listening socket, and the only
 * thing in the world that can reach http://192.168.4.2/ is the Web tab in this
 * page. Nothing outside the browser can, ever.
 *
 * Press Run, open the Web tab, and press On. The LED on GPIO 8 (and any LED
 * you have wired to it) follows the page.
 */
#include <WebServer.h>
#include <WiFi.h>

const char *SSID = "Mokxi-Lab";
const char *PASSWORD = "breadboard";

WebServer server(80);
bool lampOn = false;

void sendPage() {
  String page("<!doctype html><html><head><meta charset=\"utf-8\">");
  page += "<title>Mokxi lamp</title></head><body>";
  page += "<h1>The lamp is ";
  page += lampOn ? "ON" : "OFF";
  page += "</h1><p><a href=\"/on\">On</a> &middot; <a href=\"/off\">Off</a></p>";
  page += "<p><form method=\"post\" action=\"/set\">";
  page += "<button name=\"lamp\" value=\"toggle\">Toggle</button></form></p>";
  page += "<p>Served by the sketch on a simulated network.</p>";
  page += "</body></html>";
  server.send(200, "text/html", page);
}

void applyLamp() {
  digitalWrite(LED_BUILTIN, lampOn ? HIGH : LOW);
  Serial.print("lamp ");
  Serial.println(lampOn ? "on" : "off");
}

void handleRoot() { sendPage(); }

void handleOn() {
  lampOn = true;
  applyLamp();
  sendPage();
}

void handleOff() {
  lampOn = false;
  applyLamp();
  sendPage();
}

void handleSet() {
  if (server.arg("lamp") == "toggle") {
    lampOn = !lampOn;
    applyLamp();
  }
  sendPage();
}

void setup() {
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);

  Serial.println("Simulated WiFi: only the Web panel can reach this server.");
  WiFi.begin(SSID, PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(250);
  }
  Serial.println();
  Serial.print("open http://");
  Serial.print(WiFi.localIP());
  Serial.println("/ in the Web tab");

  server.on("/", handleRoot);
  server.on("/on", handleOn);
  server.on("/off", handleOff);
  server.on("/set", handleSet);
  server.begin();
}

void loop() {
  server.handleClient();
  delay(2);
}