Touch lamp on an Arduino Uno

// Touch lamp: the Arduino Starter Kit's "Touchy-feely Lamp". A piece of foil
// on pin 2, a 1 megohm resistor from pin 4 to it, and the CapacitiveSensor
// library counting how long the foil takes to follow pin 4.
//
//   1 M resistor  pin 4 to pin 2
//   foil          pin 2
//   lamp          the Uno's own LED on pin 13
//
// The foil is a tiny capacitor, a few picofarads. Each time pin 4 changes,
// the library counts loop passes until pin 2 follows it through the
// resistor, which takes about R times C. A finger on the foil adds roughly a
// hundred picofarads, so the count climbs several times over, and past the
// threshold the lamp comes on. capacitiveSensor() takes away the lowest count
// it has seen, so the untouched foil reads near zero.
//
// Things to try. Hold the foil and watch the count. Then change the foil's
// finger property in the panel: a smaller number is a lighter touch, and
// below the threshold it no longer lights the lamp.

#include <CapacitiveSensor.h>

CapacitiveSensor capSensor = CapacitiveSensor(4, 2);

const int LAMP_PIN = 13;
const long THRESHOLD = 100;

unsigned long lastPrint = 0;

void setup() {
  Serial.begin(9600);
  pinMode(LAMP_PIN, OUTPUT);
  Serial.println("Touch lamp ready");
}

void loop() {
  long sensorValue = capSensor.capacitiveSensor(30);
  digitalWrite(LAMP_PIN, sensorValue > THRESHOLD ? HIGH : LOW);
  if (millis() - lastPrint >= 250) {
    lastPrint = millis();
    Serial.println(sensorValue);
  }
  delay(10);
}