Alarm clock on an Arduino Uno

// Alarm clock: a DS1302 clock module, a TM1637 display, a piezo and a button.
//
//   pins 4, 5, 2  the DS1302's DAT, CLK and RST (ThreeWire's IO, SCLK, CE)
//   pins 7, 6     the TM1637's CLK and DIO
//   pin 8         the piezo; its other leg to ground
//   pin 3         the button, to ground (INPUT_PULLUP: pressed reads LOW)
//
// The display shows the hours and minutes with the colon blinking once a
// second. At 7:00 the alarm beeps in fours until the button is pressed; the
// clock module was set to 6:59:50, so it goes off ten seconds after Run.

#include <ThreeWire.h>
#include <RtcDS1302.h>
#include <TM1637Display.h>

const int PIEZO = 8;
const int BUTTON = 3;
const uint8_t ALARM_HOUR = 7;
const uint8_t ALARM_MINUTE = 0;

ThreeWire myWire(4, 5, 2);
RtcDS1302<ThreeWire> Rtc(myWire);
TM1637Display display(7, 6);

bool ringing = false;
bool doneToday = false;
uint8_t lastSecond = 99;

void setup() {
  Serial.begin(115200);
  Serial.println("Mokxi Arduino Uno: alarm clock");
  pinMode(BUTTON, INPUT_PULLUP);
  display.setBrightness(0x0f);
  Rtc.Begin();
  if (Rtc.GetIsWriteProtected()) Rtc.SetIsWriteProtected(false);
  if (!Rtc.GetIsRunning()) {
    Serial.println("clock was stopped: starting it");
    Rtc.SetIsRunning(true);
  }
}

void loop() {
  RtcDateTime now = Rtc.GetDateTime();
  if (now.Second() != lastSecond) {
    lastSecond = now.Second();
    uint8_t colon = (now.Second() % 2 == 0) ? 0b01000000 : 0;
    display.showNumberDecEx(now.Hour() * 100 + now.Minute(), colon, true);
    Serial.print(now.Hour());
    Serial.print(':');
    if (now.Minute() < 10) Serial.print('0');
    Serial.print(now.Minute());
    Serial.print(':');
    if (now.Second() < 10) Serial.print('0');
    Serial.println(now.Second());
  }

  bool alarmTime = now.Hour() == ALARM_HOUR && now.Minute() == ALARM_MINUTE;
  if (alarmTime && !doneToday && !ringing) {
    ringing = true;
    Serial.println("alarm!");
  }
  if (!alarmTime) doneToday = false;

  if (ringing) {
    // Four short beeps, then a rest, until the button.
    for (int i = 0; i < 4 && ringing; i++) {
      tone(PIEZO, 2000, 80);
      delay(150);
      if (digitalRead(BUTTON) == LOW) ringing = false;
    }
    delay(300);
    if (digitalRead(BUTTON) == LOW) ringing = false;
    if (!ringing) {
      noTone(PIEZO);
      doneToday = true;
      Serial.println("alarm off");
    }
  } else {
    delay(50);
  }
}