Two barometers on an ESP32-C3

// Two pressure sensors on one I2C bus: a BME280 at 0x76 and a BMP280 at 0x77,
// on the ESP32-C3's own I2C pins, GPIO 8 (SDA) and GPIO 9 (SCL).
//
// The two chips are the same die, less the humidity sensor on the BMP280, and
// on their purple boards they look identical. The address strap is what lets
// both share one bus, and the chip-id register, 0x60 or 0x58, is how the
// sketch tells which is which.
//
// Neither reports degrees or pascals. Each reports raw counts and carries its
// own factory calibration, and the datasheet's integer formulas turn one into
// the other: mokxi_bme280.h is those formulas. The temperature is always
// worked first, because the pressure and humidity formulas need a by-product
// of it. The altitude is the barometric formula against 1013.25 hPa, worked in
// integers too.
//
// Drag the pressure sliders: every 12 hPa or so is a hundred metres.

#include <Wire.h>
#include "mokxi_bme280.h"

MokxiBme280 sensor[2];
const uint8_t ADDRESS[2] = {0x76, 0x77};

// A whole number of hundredths (or tenths) printed with its decimal point.
void printFixed(long value, long scale) {
  if (value < 0) {
    Serial.print('-');
    value = -value;
  }
  Serial.print(value / scale);
  Serial.print('.');
  long rest = value % scale;
  for (long digit = scale / 10; digit > 1 && rest < digit; digit /= 10) Serial.print('0');
  Serial.print(rest);
}

void setup() {
  Serial.begin(9600);
  Wire.begin();
  for (int i = 0; i < 2; i++) {
    Serial.print("0x");
    Serial.print(ADDRESS[i], HEX);
    if (!sensor[i].begin(&Wire, ADDRESS[i])) {
      Serial.println(": nothing there");
      continue;
    }
    Serial.println(sensor[i].humid() ? ": BME280, id 0x60" : ": BMP280, id 0x58");
    // Normal mode, 2x temperature, 16x pressure, 1x humidity, filter 4.
    sensor[i].configure(0x01, (0x02 << 5) | (0x05 << 2) | 0x03, 0x02 << 2);
  }
}

void loop() {
  delay(1000);
  for (int i = 0; i < 2; i++) {
    if (sensor[i].id() == 0) continue;
    int32_t t, p, h;
    if (!sensor[i].readRaw(t, p, h)) continue;
    long hundredths = sensor[i].temperature100(t);  // first: it sets t_fine
    long pascals = (long)sensor[i].pressurePa(p);
    Serial.print(sensor[i].humid() ? "BME280 " : "BMP280 ");
    printFixed(hundredths, 100);
    Serial.print(" C  ");
    printFixed(pascals, 100);
    Serial.print(" hPa  ");
    printFixed(mokxi_altitude_cm((uint32_t)pascals, 101325u) / 10, 10);
    Serial.print(" m");
    if (sensor[i].humid()) {
      Serial.print("  ");
      printFixed((long)sensor[i].humidity1024(h) * 10 / 1024, 10);
      Serial.print(" %RH");
    }
    Serial.println();
  }
}