LoRa messenger on an Arduino Uno

// LoRa messenger, the sending end.
//
// A Ra-02 (SX1278) on SPI, driven by LoRa.h with its default pins: NSS on 10,
// RESET on 9 and DIO0 on 2. Every two seconds it sends a numbered message at
// 433 MHz and prints how long the packet took on the air. At the default
// spreading factor of 7 that is a few tens of milliseconds; change it with
// LoRa.setSpreadingFactor() on both boards and watch the time grow.

#include <SPI.h>
#include <LoRa.h>

int counter = 0;

void setup()
{
    Serial.begin(9600);
    Serial.println("LoRa Sender");
    if (!LoRa.begin(433E6)) {
        Serial.println("Starting LoRa failed!");
        while (1) {
        }
    }
}

void loop()
{
    Serial.print("Sending packet: ");
    Serial.println(counter);
    unsigned long start = millis();
    LoRa.beginPacket();
    LoRa.print("hello ");
    LoRa.print(counter);
    LoRa.endPacket();
    Serial.print("  on the air for ");
    Serial.print(millis() - start);
    Serial.println(" ms");
    counter++;
    delay(2000);
}

// LoRa messenger, the receiving end.
//
// The same module and pins as the sender, on the same frequency. parsePacket()
// puts the radio in single receive mode and returns the length of a packet
// once one has come in; then the bytes are read one at a time. The signal
// strength is a fixed -45 dBm in the simulator, which has no distance.

#include <SPI.h>
#include <LoRa.h>

void setup()
{
    Serial.begin(9600);
    Serial.println("LoRa Receiver");
    if (!LoRa.begin(433E6)) {
        Serial.println("Starting LoRa failed!");
        while (1) {
        }
    }
}

void loop()
{
    int packetSize = LoRa.parsePacket();
    if (packetSize) {
        Serial.print("Received packet '");
        while (LoRa.available()) {
            Serial.print((char)LoRa.read());
        }
        Serial.print("' with RSSI ");
        Serial.println(LoRa.packetRssi());
    }
}