KY comparator boards and an IR switch on an Arduino Uno

// Four KY comparator boards on pins 2 to 5, and an E18-D80NK on pin 6.
//
//   KY-024 Hall D0 -> pin 2      KY-025 reed D0 -> pin 3
//   KY-028 thermistor D0 -> pin 4   KY-037 sound D0 -> pin 5
//   E18-D80NK black (OUT) -> pin 6
//   every + (brown) -> 5V   every G (blue) -> GND
//
// On these boards D0 goes HIGH, and the board's own lamp lights, when the
// sensor passes the trimmer: a south pole at the Hall sensor, a magnet at the
// reed, a warm thermistor, a loud sound. The sound board's D0 is a burst of
// short pulses on a clap, so the sketch holds "loud" for half a second after
// the last one.
//
// The E18-D80NK is the other way around: its NPN open collector pulls pin 6
// LOW while something is within its range and drives nothing otherwise, so
// pin 6 needs a pull-up, and INPUT_PULLUP gives it one.
//
// Drag the magnets, the temperature and the target, and clap.

const int pins[] = {2, 3, 4, 5};
const char *names[] = {"field", "magnet", "warm", "loud"};
int last[] = {-1, -1, -1, -1};
int lastNear = -1;
unsigned long heard = 0;

void setup() {
  for (int i = 0; i < 4; i++) pinMode(pins[i], INPUT);
  pinMode(6, INPUT_PULLUP);
  Serial.begin(9600);
  Serial.println("Mokxi Uno: KY comparator boards on 2 to 5, IR switch on 6");
}

void loop() {
  if (digitalRead(5) == HIGH) heard = millis();
  for (int i = 0; i < 4; i++) {
    int now = digitalRead(pins[i]) == HIGH ? 1 : 0;
    if (i == 3) now = heard != 0 && millis() - heard < 500 ? 1 : 0;
    if (now != last[i]) {
      last[i] = now;
      Serial.print(names[i]);
      Serial.println(now ? " on" : " off");
    }
  }
  int near = digitalRead(6) == LOW ? 1 : 0;
  if (near != lastNear) {
    lastNear = near;
    Serial.println(near ? "something there" : "clear");
  }
}