ESP32 Telegram doorbell with a PIR sensor

/*
 * ESP32 Telegram doorbell: press the button and the buzzer rings and your
 * phone gets a Telegram message. A PIR sensor at the door sends another when
 * someone moves there, at most once a minute.
 *
 *   Button   one side -> GPIO 4 (D4), other side -> GND (INPUT_PULLUP)
 *   Buzzer   active buzzer, + -> GPIO 25 (D25), - -> GND
 *   PIR      HC-SR501, VCC -> 5 V, OUT -> GPIO 27 (D27), GND -> GND
 *            (its output is 3.3 V, safe for the ESP32)
 *
 * Library: UniversalTelegramBot (Brian Lough), which needs ArduinoJson.
 *
 * Before uploading to a real board:
 *   1. In Telegram, talk to @BotFather, send /newbot and copy the token it
 *      gives you into BOT_TOKEN.
 *   2. Talk to @userinfobot to get your chat id, and put it in CHAT_ID.
 *   3. Send your new bot any message once, so it is allowed to message you.
 *   4. Put your WiFi name and password in SSID and PASSWORD.
 *
 * In Mokxi the buzzer and the Serial Monitor work as soon as you press Run.
 * The message itself goes out only with Real internet switched on in the
 * Cloud panel (signed in) and a real token; otherwise the Serial Monitor
 * says why nothing was sent, and the doorbell still rings.
 */
#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>

const char *SSID = "Mokxi-Lab";
const char *PASSWORD = "breadboard";

#define BOT_TOKEN "123456789:REPLACE_WITH_YOUR_BOT_TOKEN"
#define CHAT_ID "123456789"

const int BUTTON_PIN = 4;
const int BUZZER_PIN = 25;
const int PIR_PIN = 27;

const unsigned long MOTION_GAP_MS = 60000; // one motion message a minute at most

WiFiClientSecure client;
UniversalTelegramBot bot(BOT_TOKEN, client);

unsigned long lastMotionMessage = 0;
bool motionSentOnce = false;
int rings = 0;

void ring()
{
    // ding ... dong: two beeps from an active buzzer
    digitalWrite(BUZZER_PIN, HIGH);
    delay(300);
    digitalWrite(BUZZER_PIN, LOW);
    delay(150);
    digitalWrite(BUZZER_PIN, HIGH);
    delay(500);
    digitalWrite(BUZZER_PIN, LOW);
}

void notify(const String &text)
{
    if (bot.sendMessage(CHAT_ID, text, "")) {
        Serial.println("Telegram message sent");
    } else {
        Serial.println("Telegram message NOT sent");
    }
}

void setup()
{
    Serial.begin(115200);
    pinMode(BUTTON_PIN, INPUT_PULLUP);
    pinMode(BUZZER_PIN, OUTPUT);
    pinMode(PIR_PIN, INPUT);

    Serial.print("Connecting to ");
    Serial.println(SSID);
    WiFi.begin(SSID, PASSWORD);
    client.setCACert(TELEGRAM_CERTIFICATE_ROOT); // api.telegram.org's root certificate
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
    Serial.println();
    Serial.print("WiFi connected, IP ");
    Serial.println(WiFi.localIP());
    Serial.println("Doorbell ready");
}

void loop()
{
    if (digitalRead(BUTTON_PIN) == LOW) {
        rings++;
        Serial.print("Ding dong! Ring ");
        Serial.println(rings);
        ring();
        notify("Ding dong! Someone is at the door.");
        // wait for the button to be let go, so one press is one ring
        while (digitalRead(BUTTON_PIN) == LOW) delay(10);
        delay(50);
    }

    if (digitalRead(PIR_PIN) == HIGH) {
        unsigned long now = millis();
        if (!motionSentOnce || now - lastMotionMessage >= MOTION_GAP_MS) {
            motionSentOnce = true;
            lastMotionMessage = now;
            Serial.println("Motion at the door");
            notify("Motion at the front door.");
        }
    }
    delay(20);
}