ESP32 Bluetooth serial lamp

// Bluetooth lamp: the ESP32's own Bluetooth serial port switches an LED.
//
// Simulated Bluetooth: a phone in Mokxi, not a real radio. Press Run, open
// the Bluetooth tab, pair with ESP32-Lamp and connect, then send on, off or
// status. The same sketch runs unchanged on a real ESP32 with the "Serial
// Bluetooth Terminal" app on a phone.

#include "BluetoothSerial.h"

BluetoothSerial SerialBT;
const int kLed = 4; // an LED and a resistor to ground

void onBluetooth(esp_spp_cb_event_t event, esp_spp_cb_param_t *param)
{
    if (event == ESP_SPP_SRV_OPEN_EVT) {
        Serial.println("A phone connected.");
        SerialBT.println("Hello from ESP32-Lamp. Send on, off or status.");
    } else if (event == ESP_SPP_CLOSE_EVT) {
        Serial.println("The phone disconnected.");
    }
}

void setup()
{
    Serial.begin(115200);
    pinMode(kLed, OUTPUT);
    pinMode(LED_BUILTIN, OUTPUT);
    SerialBT.register_callback(onBluetooth);
    SerialBT.begin("ESP32-Lamp");
    Serial.println("ESP32-Lamp is ready: pair with it from the Bluetooth tab.");
}

void loop()
{
    // The blue LED on the board shows whether a phone is connected.
    digitalWrite(LED_BUILTIN, SerialBT.hasClient() ? HIGH : LOW);

    if (SerialBT.available()) {
        String line = SerialBT.readStringUntil('\n');
        line.trim();
        line.toLowerCase();
        Serial.print("Phone sent: ");
        Serial.println(line);
        if (line == "on") {
            digitalWrite(kLed, HIGH);
            SerialBT.println("The lamp is on.");
        } else if (line == "off") {
            digitalWrite(kLed, LOW);
            SerialBT.println("The lamp is off.");
        } else if (line == "status") {
            SerialBT.println(digitalRead(kLed) ? "The lamp is on." : "The lamp is off.");
        } else if (line.length() > 0) {
            SerialBT.println("Send on, off or status.");
        }
    }
    delay(20);
}