PMS5003 dust monitor on an Arduino Uno

// Dust monitor: a Plantower PMS5003 laser particle sensor and a 16x2 I2C LCD.
//
//   PMS5003 TX -> pin 2    PMS5003 RX <- pin 3    VCC -> 5 V    GND -> GND
//   LCD     SDA -> A4      SCL -> A5              VCC -> 5 V    GND -> GND
//
// The sensor sends a 32 byte frame at 9600 baud about every two seconds: PM1.0,
// PM2.5 and PM10 in micrograms per cubic meter. The PMS library takes the
// frame one byte per read() call, so loop() calls it as often as it can and
// does the printing only when a whole frame has arrived.
//
// The second line grades the PM2.5 with the US EPA's 24 hour bands: Good up to
// 12, Moderate up to 35, "Unhealthy SG" (sensitive groups) up to 55, Unhealthy
// over that. A real room needs the 30 seconds the sensor asks for after power
// on before its numbers settle; here the first frame is already right.
//
// Drag the PM2.5 slider on the sensor and watch the grade change.

#include <LiquidCrystal_I2C.h>
#include <PMS.h>
#include <SoftwareSerial.h>

SoftwareSerial pmsSerial(2, 3);  // RX (the sensor's TX), TX (the sensor's RX)
PMS pms(pmsSerial);
PMS::DATA data;
LiquidCrystal_I2C lcd(0x27, 16, 2);

const char *grade(uint16_t pm25) {
  if (pm25 <= 12) return "Good";
  if (pm25 <= 35) return "Moderate";
  if (pm25 <= 55) return "Unhealthy SG";
  return "Unhealthy";
}

void setup() {
  Serial.begin(115200);
  pmsSerial.begin(PMS::BAUD_RATE);
  lcd.init();
  lcd.backlight();
  lcd.print("Waiting for PMS");
  Serial.println("PMS5003 dust monitor");
}

void loop() {
  if (!pms.read(data)) return;

  Serial.print("PM1.0 ");  Serial.print(data.PM_AE_UG_1_0);
  Serial.print("  PM2.5 "); Serial.print(data.PM_AE_UG_2_5);
  Serial.print("  PM10 ");  Serial.println(data.PM_AE_UG_10_0);

  lcd.clear();
  lcd.print("PM2.5 ");
  lcd.print(data.PM_AE_UG_2_5);
  lcd.print(" PM10 ");
  lcd.print(data.PM_AE_UG_10_0);
  lcd.setCursor(0, 1);
  lcd.print(grade(data.PM_AE_UG_2_5));
}