Breathing LED on an ESP32-C3

// Fade: a breathing LED from software PWM on GPIO 8.
//
// The ESP32-C3 has an LED PWM peripheral, but Mokxi does not model it, so
// this bit-bangs it: a 1 kHz square wave whose high time is the brightness.
// delayMicroseconds is accurate to a couple of instructions in the simulator,
// so the waveform is clean.
//
// The table is one cycle of (1 - cos)/2, which is what makes the light look
// like it is breathing rather than ramping. Values are 0..250 microseconds
// times four, so a step is 0..1000 us of the 1000 us period.

const unsigned long PERIOD_US = 1000;   // 1 kHz
const int STEPS = 64;
const int CYCLES_PER_STEP = 30;         // 30 ms at each brightness

const uint8_t breath[STEPS] = {
    0,   1,   2,   5,  10,  15,  21,  28,
   37,  46,  56,  66,  77,  89, 101, 113,
  125, 137, 149, 161, 173, 184, 194, 204,
  213, 222, 229, 235, 240, 245, 248, 249,
  250, 249, 248, 245, 240, 235, 229, 222,
  213, 204, 194, 184, 173, 161, 149, 137,
  125, 113, 101,  89,  77,  66,  56,  46,
   37,  28,  21,  15,  10,   5,   2,   1,
};

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
  for (int step = 0; step < STEPS; step++) {
    unsigned long onTime = (unsigned long)breath[step] * 4;
    unsigned long offTime = PERIOD_US - onTime;

    for (int cycle = 0; cycle < CYCLES_PER_STEP; cycle++) {
      if (onTime > 0) {
        digitalWrite(LED_BUILTIN, HIGH);
        delayMicroseconds(onTime);
      }
      if (offTime > 0) {
        digitalWrite(LED_BUILTIN, LOW);
        delayMicroseconds(offTime);
      }
    }
  }
}