PWM ESP32 với ledcAttach và ledcWrite
Cơ bản
Hoặc xem mọi bài học.
- 526linh kiện trên bàn làm mạch
- 46bo mạch đang chạy
- 1.00xthời gian thực, trên mọi bo mạch
ESP32 không có chân PWM cố định. PWM của nó đến từ một khối gọi là LEDC, và bất kỳ chân nào có driver đầu ra cũng có thể là một đầu ra của khối này. Từ phiên bản 3.0 của Arduino ESP32 core, hai lệnh gọi là đủ cho mọi việc: ledcAttach(pin, frequency, bits) thiết lập chân, và ledcWrite(pin, duty) đặt mức cao trong bao nhiêu phần của mỗi chu kỳ. analogWrite() cũng hoạt động, trên cùng một phần cứng.
Mạch phía trên là một ESP32 DevKit với biến trở trên GPIO 32 và LED trên GPIO 4. Sketch đọc núm xoay và gọi analogWrite(4, duty), nên xoay núm sẽ chỉnh độ sáng LED, và Serial Monitor hiển thị giá trị đọc được và độ rộng xung đã chọn. Phần dưới đây cho thấy các lệnh gọi LEDC làm gì, được đo trên chính bo mạch đó, và điều gì đã thay đổi so với core 2.x mà đa số hướng dẫn vẫn dùng.
ledcAttach và ledcWrite
Sketch dưới đây gắn GPIO 4 ở 5000 Hz với độ phân giải 8 bit, nên độ rộng xung chạy từ 0 đến 255, và ghi giá trị 64, tức một phần tư. Một dây cắm từ GPIO 4 sang GPIO 15 cho phép chính bo mạch đo đầu ra của nó bằng pulseIn(). Nó in ra "high 50 us, low 150 us": chu kỳ 200 microgiây, tương ứng 5000 Hz, mức cao trong một phần tư chu kỳ.
ledcAttach() trả về true khi tìm được một kênh và một timer cho chân, và false khi không tìm được, nên hãy kiểm tra nó. Ở đây nó thất bại trên GPIO 34, một trong các chân chỉ có đầu vào, vốn không có driver đầu ra. Chân là tên dùng cho mọi lệnh sau đó: ledcWrite(4, 128) cho một nửa, ledcRead(4) để đọc độ rộng xung, ledcReadFreq(4) để đọc tần số, và ledcDetach(4) để trả lại kênh.
const int kLed = 4;
const int kProbe = 15; // a jumper from GPIO 4
void setup() {
Serial.begin(115200);
pinMode(kProbe, INPUT);
if (!ledcAttach(kLed, 5000, 8)) {
Serial.println("ledcAttach failed");
}
ledcWrite(kLed, 64); // 64 of 256: a quarter
delay(5);
Serial.print("high ");
Serial.print(pulseIn(kProbe, HIGH));
Serial.print(" us, low ");
Serial.print(pulseIn(kProbe, LOW));
Serial.println(" us");
}
void loop() {
}Mở sketch này trong trình soạn codeChỉ riêng phần code: trình soạn code sẽ tự đặt bo mạch và các linh kiện mà nó đọc được từ sketch.
analogWrite so với ledcWrite
Trên ESP32, analogWrite(pin, value) gắn chân vào một kênh ở lần gọi đầu tiên, với 8 bit và 1000 Hz, rồi ghi giá trị. Với analogWrite(4, 64), cùng phép đo đó in ra "high 250 us, low 750 us": chu kỳ 1 kHz, mức cao một phần tư. Đây là lệnh gọi phù hợp cho LED và cho code cũng cần biên dịch được cho Uno.
Khi tần số quan trọng, hãy đặt riêng cho từng chân trước khi ghi. analogWriteFrequency(4, 5000) và analogWriteResolution(4, 10), rồi analogWrite(4, 256), in ra lại "high 50 us, low 150 us", vì 256 trên 1024 là một phần tư. Driver động cơ, quạt hoặc còi buzzer thường cần tần số riêng, và servo cần 50 Hz, vì vậy đa số hướng dẫn về ESP32 dùng trực tiếp các lệnh LEDC.
Tần số đối với độ phân giải
Bộ đếm thời gian LEDC đếm một xung nhịp, và một chu kỳ là 2 lũy thừa của độ phân giải số đếm. Trên ESP32 đời đầu, xung nhịp nhanh nhất là xung nhịp APB 80 MHz, nên tần số nhân 2 lũy thừa số bit phải dưới 80 triệu (hướng dẫn LEDC của Espressif). Như vậy được 13 bit ở 5 kHz, 11 bit ở 20 kHz và 10 bit ở 40 kHz. Yêu cầu hơn thế thì ESP32 thật sẽ từ chối lệnh attach.
Mokxi chưa kiểm tra giới hạn đó: nó chấp nhận mọi tần số với tối đa 14 bit, nên một cặp chạy được ở đây vẫn có thể lỗi trên bo mạch. Hãy chọn cặp theo phép tính ở trên. Với LED, 5 kHz ở 8 bit là quá đủ. Với động cơ không nên kêu ù ù, dùng 20 kHz ở 10 bit hoặc ít hơn.
ledcChangeFrequency(pin, frequency, bits) chỉnh lại tần số cho một chân đã được gắn, còn ledcWriteTone(pin, 440) phát sóng vuông với chu kỳ nhiệm vụ một nửa, đó là cách buzzer thụ động phát một nốt nhạc. Ở đây hàm trả về 440, và nửa cao của mỗi chu kỳ đo được 1130 microgiây, đúng bằng nửa chu kỳ của 440 Hz.
ESP32 có bao nhiêu kênh PWM?
Mỗi kênh điều khiển một chân, và các kênh cùng tần số và độ phân giải dùng chung một bộ đếm thời gian. Bảng của Espressif cho ESP32 đời đầu 16 kênh chia hai nhóm, S3 có tám và C3 có sáu, mỗi nhóm bốn bộ đếm thời gian. Core 3.x tự phân phối; ledcAttachChannel(pin, frequency, bits, channel) chọn kênh khi bạn cần.
ESP32 đời đầu trong Mokxi mô phỏng nhóm tốc độ cao: tám kênh và bốn bộ đếm thời gian. Gắn chân này đến chân khác ở 5000 Hz thì lần ledcAttach() thứ chín ở đây trả về 0. Gắn mỗi chân ở một tần số khác nhau thì lần thứ năm trả về 0, vì mỗi tần số cần một bộ đếm thời gian riêng. ESP32 thật còn có nhóm thứ hai nên cùng sketch đó đi được gấp đôi, và bài học vẫn thế: các đèn muốn mờ dần cùng nhau nên dùng chung một tần số.
"ledcSetup was not declared in this scope"
Đây là lỗi mà gần như ai cũng gặp sau khi cập nhật gói bo mạch ESP32. Core 3.0 đã bỏ ledcSetup() và ledcAttachPin(), gộp chúng thành ledcAttach(), và mọi lệnh LEDC giờ nhận chân thay vì số kênh (hướng dẫn chuyển từ 2.x sang 3.0 của Espressif). Sketch viết cho 2.x sẽ dừng lại trong Arduino IDE với 'ledcSetup' was not declared in this scope. ledcDetachPin() trở thành ledcDetach().
Mokxi chấp nhận cả hai cách viết, nên một tutorial cũ chạy ở đây không cần sửa: ledcSetup(0, 5000, 8) trả về 5000, và sau ledcAttachPin(4, 0) với ledcWrite(0, 64) thì chân đo được "high 50 us" như trước. Đó là tiện lợi của Mokxi, không phải cách Arduino IDE làm, nên hãy chuyển sketch trước khi đem lên bo mạch. Chuyển từ ba dòng thành hai: bỏ số kênh, gắn theo chân, ghi theo chân.
// Core 2.x: by channel
ledcSetup(0, 5000, 8);
ledcAttachPin(4, 0);
ledcWrite(0, 64);
// Core 3.x: by pin
ledcAttach(4, 5000, 8);
ledcWrite(4, 64);Mở mạch này trong trình soạn thảo. ESP32 DevKit: một chiết áp chỉnh độ sáng LED trên GPIO 4, nối dây như khi chạy ở đầu trang này. Đổi linh kiện hoặc giá trị rồi chạy lại nhé.
Mở mạchCâu hỏi
Chân nào của ESP32 làm được PWM?
Bất kỳ chân có bộ kéo đầu ra: LEDC đến các pad qua ma trận GPIO. Không phải GPIO 34 đến 39 vì chỉ vào, và tốt nhất không dùng GPIO 6 đến 11 vì là flash.
Làm sao sửa lỗi "ledcSetup was not declared in this scope"?
Bạn đang có core 3.x và sketch cho 2.x. Thay ledcSetup(channel, freq, bits) và ledcAttachPin(pin, channel) bằng ledcAttach(pin, freq, bits), và truyền chân cho ledcWrite thay vì kênh.
Nên dùng analogWrite hay ledcWrite trên ESP32?
analogWrite cho LED ở mặc định 1 kHz và 8 bit, hoặc cho code dùng chung với Uno. ledcAttach và ledcWrite khi tần số hay độ phân giải quan trọng, như servo, driver động cơ hay buzzer.
Sao ledcWrite trên ESP32 của mình không chạy?
Thường là sketch 2.x chạy trên core 3.x: ledcWrite(0, duty) giờ nghĩa là chân 0, không phải kênh 0. Nếu không thì ledcAttach lỗi (kiểm tra giá trị trả về), chân chỉ ở chế độ đầu vào, hoặc tần số và độ phân giải không khớp xung nhịp 80 MHz.
Nên dùng tần số PWM bao nhiêu trên ESP32?
5 kHz ở 8 đến 13 bit cho LED, 20 kHz ở tối đa 11 bit cho động cơ mà bạn không muốn nghe tiếng, 50 Hz cho servo, và chính nốt nhạc cho buzzer, bằng ledcWriteTone.
Tiếp tục nào
Thông tin trên trang này lấy từ đâu
Lắp mạch này ngoài đời
Mở trình soạn thảo, đổi một giá trị và xem con số thay đổi theo. Không cần cài gì, không cần tài khoản.