Belajar

ESP32 PWM dengan ledcAttach dan ledcWrite

Pemula

Atau lihat semua pelajaran.

  • 526komponen di meja kerja
  • 46board sedang berjalan
  • 1.00xwaktu nyata, di semua board
ESP32 DevKit: knob yang meredupkan LED di GPIO 4live0.000 s 0.00x
Klik untuk membukanya di editor
analogWrite() di GPIO 4 berjalan di kanal LEDC: delapan bit pada 1 kHz.

ESP32 tidak punya pin PWM tetap. PWM-nya berasal dari blok bernama LEDC, dan pin apa pun dengan output driver bisa menjadi salah satu outputnya. Sejak versi 3.0 core Arduino ESP32, dua panggilan mengurus semuanya: ledcAttach(pin, frequency, bits) menyiapkan pin, dan ledcWrite(pin, duty) mengatur seberapa lama tiap perioda berlogika tinggi. analogWrite() juga bisa, di atas perangkat keras yang sama.

Rangkaian di atas adalah ESP32 DevKit dengan potentiometer di GPIO 32 dan LED di GPIO 4. Sketch membaca knob dan memanggil analogWrite(4, duty), jadi memutar knob meredupkan LED, dan Serial Monitor menunjukkan pembacaan dan duty yang dipilihnya. Di bawah adalah apa yang dilakukan panggilan LEDC, diukur di board yang sama, dan apa yang berubah dari core 2.x yang masih dipakai kebanyakan tutorial.

ledcAttach dan ledcWrite

Sketch di bawah meng-attach GPIO 4 pada 5000 Hz dengan resolusi 8 bit, jadi duty berjalan dari 0 sampai 255, dan menulis 64, seperempatnya. Jumper dari GPIO 4 ke GPIO 15 memungkinkan board yang sama mengukur outputnya sendiri dengan pulseIn(). Ia mencetak "high 50 us, low 150 us": perioda 200 mikrodetik, yaitu 5000 Hz, tinggi selama seperempatnya.

ledcAttach() mengembalikan true saat menemukan kanal dan timer untuk pin, dan false saat tidak, jadi periksa nilainya. Di sini gagal di GPIO 34, salah satu pin input-only, yang sama sekali tidak punya output driver. Pin adalah nama untuk semuanya setelahnya: ledcWrite(4, 128) untuk setengah, ledcRead(4) untuk duty, ledcReadFreq(4) untuk frekuensi, dan ledcDetach(4) untuk mengembalikan kanalnya.

ledcAttach pada 5 kHz, diukur dengan pulseIn
const int kLed = 4;
const int kProbe = 15;   // a jumper from GPIO 4

void setup() {
  Serial.begin(115200);
  pinMode(kProbe, INPUT);
  if (!ledcAttach(kLed, 5000, 8)) {
    Serial.println("ledcAttach failed");
  }
  ledcWrite(kLed, 64);   // 64 of 256: a quarter
  delay(5);
  Serial.print("high ");
  Serial.print(pulseIn(kProbe, HIGH));
  Serial.print(" us, low ");
  Serial.print(pulseIn(kProbe, LOW));
  Serial.println(" us");
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

analogWrite dibandingkan dengan ledcWrite

Di ESP32, analogWrite(pin, value) meng-attach pin ke kanal saat pertama kali dipanggil, pada 8 bit dan 1000 Hz, lalu menulis nilainya. Dengan analogWrite(4, 64) pengukuran yang sama mencetak "high 250 us, low 750 us": perioda 1 kHz, seperempatnya tinggi. Ini panggilan yang tepat untuk LED dan untuk kode yang juga harus bisa dikompilasi untuk Uno.

Saat frekuensi penting, atur per pin sebelum menulis. analogWriteFrequency(4, 5000) dan analogWriteResolution(4, 10), lalu analogWrite(4, 256), mencetak "high 50 us, low 150 us" lagi, karena 256 dari 1024 adalah seperempat. Driver motor, kipas, atau buzzer biasanya butuh frekuensi sendiri, dan servo butuh 50 Hz, karena itu kebanyakan tutorial ESP32 memakai panggilan LEDC langsung.

Frekuensi dibandingkan dengan resolusi

Timer LEDC menghitung sebuah clock, dan satu periode adalah 2 pangkat resolusi hitungan. Pada ESP32 klasik clock tercepat adalah clock APB 80 MHz, jadi frekuensi dikali 2 pangkat jumlah bit harus tetap di bawah 80 juta (panduan LEDC dari Espressif). Itu memungkinkan 13 bit pada 5 kHz, 11 bit pada 20 kHz, dan 10 bit pada 40 kHz. Minta lebih dari itu dan ESP32 sungguhan menolak attach-nya.

Mokxi belum memeriksa batas itu: ia menerima frekuensi apa pun hingga 14 bit, jadi pasangan yang berhasil di sini masih bisa gagal di board. Pilih pasangannya dari perhitungan di atas. Untuk LED, 5 kHz pada 8 bit sudah cukup. Untuk motor yang tidak boleh berdengung, 20 kHz pada 10 bit atau kurang.

ledcChangeFrequency(pin, frequency, bits) mengatur ulang frekuensi pin yang sudah di-attach, dan ledcWriteTone(pin, 440) memainkan gelombang kotak dengan duty setengah, begitulah cara buzzer pasif memainkan nada. Di sini ia mengembalikan 440, dan setengah bagian tinggi dari tiap periode terukur 1130 mikrodetik, setengah dari periode 440 Hz.

Berapa jumlah channel PWM pada ESP32?

Satu channel menggerakkan satu pin, dan channel pada frekuensi dan resolusi yang sama berbagi satu timer. Tabel dari Espressif memberi ESP32 klasik 16 channel dalam dua grup, S3 delapan dan C3 enam, dan tiap grup punya empat timer. Core 3.x membagikannya sendiri; ledcAttachChannel(pin, frequency, bits, channel) memilih satu saat kamu membutuhkannya.

ESP32 klasik di Mokxi memodelkan grup kecepatan tinggi: delapan channel dan empat timer. Meng-attach pin demi pin pada 5000 Hz, ledcAttach() kesembilan mengembalikan 0 di sini. Meng-attach tiap pin pada frekuensi berbeda, yang kelima mengembalikan 0, karena tiap frekuensi butuh timer sendiri. ESP32 sungguhan punya grup kedua juga, jadi sketch yang sama bisa dua kali lebih jauh, dan pelajarannya sama: lampu yang memudar bersama sebaiknya berbagi satu frekuensi.

"ledcSetup was not declared in this scope"

Ini error yang hampir semua orang temui setelah memperbarui paket board ESP32. Core 3.0 menghapus ledcSetup() dan ledcAttachPin() dan menggabungkannya menjadi ledcAttach(), dan setiap panggilan LEDC sekarang memakai pin, bukan nomor channel (panduan migrasi 2.x ke 3.0 dari Espressif). Sketch yang ditulis untuk 2.x berhenti di Arduino IDE dengan 'ledcSetup' was not declared in this scope. ledcDetachPin() menjadi ledcDetach().

Mokxi menerima dua ejaan itu, jadi tutorial lama tetap jalan di sini tanpa perubahan: ledcSetup(0, 5000, 8) mengembalikan 5000, dan setelah ledcAttachPin(4, 0) serta ledcWrite(0, 64) pin terukur "high 50 us" seperti sebelumnya. Itu cuma untuk memudahkan, bukan seperti yang dilakukan Arduino IDE, jadi porting sketch-mu sebelum membawanya ke board. Portingnya tiga baris menjadi dua: buang channel, sambungkan berdasarkan pin, tulis berdasarkan pin.

PWM yang sama di core 2.x dan core 3.x
// Core 2.x: by channel
ledcSetup(0, 5000, 8);
ledcAttachPin(4, 0);
ledcWrite(0, 64);

// Core 3.x: by pin
ledcAttach(4, 5000, 8);
ledcWrite(4, 64);

Buka rangkaian ini di editor. ESP32 DevKit: sebuah knob meredupkan LED di GPIO 4, dirangkai seperti yang berjalan di bagian atas halaman ini. Ubah komponen atau nilai lalu jalankan lagi.

Buka rangkaian ini

Pertanyaan

Pin ESP32 mana saja yang bisa PWM?

Pin apa pun yang punya output driver: LEDC mencapai pad melalui GPIO matrix. Bukan GPIO 34 sampai 39, yang hanya input, dan sebaiknya bukan GPIO 6 sampai 11, yang dipakai flash.

Bagaimana memperbaiki "ledcSetup was not declared in this scope"?

Kamu punya core 3.x dan sketch untuk 2.x. Ganti ledcSetup(channel, freq, bits) dan ledcAttachPin(pin, channel) dengan ledcAttach(pin, freq, bits), dan berikan pin ke ledcWrite, bukan channel.

Harus pakai analogWrite atau ledcWrite di ESP32?

analogWrite untuk LED pada 1 kHz dan 8 bit bawaan, atau untuk kode yang dibagikan dengan Uno. ledcAttach dan ledcWrite saat frekuensi atau resolusi penting, misalnya untuk servo, driver motor, atau buzzer.

Kenapa ledcWrite di ESP32-ku tidak berfungsi?

Biasanya sketch 2.x di core 3.x: ledcWrite(0, duty) sekarang berarti pin 0, bukan channel 0. Kalau bukan, ledcAttach gagal (periksa nilai kembaliannya), pin hanya input, atau frekuensi dan resolusi tidak muat dengan clock 80 MHz.

Frekuensi PWM berapa yang sebaiknya dipakai di ESP32?

5 kHz pada 8 sampai 13 bit untuk LED, 20 kHz hingga 11 bit untuk motor yang tidak boleh terdengar, 50 Hz untuk servo, dan nada itu sendiri untuk buzzer, dengan ledcWriteTone.

Rakit versi nyatanya

Buka editor, ubah sebuah nilai, dan lihat angkanya ikut berubah. Tidak ada yang perlu dipasang, dan tidak perlu akun.