Öğren

Arduino dizileri: tek isim altında bir liste

Ücretsiz kurmaya başla

Ya da tüm dersleri gör.

  • 526parça tezgahta
  • 46kart şu an çalışıyor
  • 1.00xgerçek zamanlı, her kartta
Arduino Uno: bir dizide sekiz desen, sekiz lambadacanlı0.000 s 0.00x
Düzenleyicide açmak için tıkla
Bir for döngüsü sekiz baytlık bir diziyi gezer ve her birini lambalarda gösterir.

Dizi, aynı tipte değerlerin tek isim altındaki listesidir. int pins[] = {13, 12, 11}; üç sayılık bir liste yapar, pins[0] ilk elemandır ve bir for döngüsü tüm listeyi gezebilir. Diziler, bir kodun LED pinlerinin sırasını, bir melodiyi, ışık desenleri kümesini veya son on sensör okumasını tutma yöntemidir.

Yukarıdaki devre sekiz ışık desenini bir dizide tutar ve bunları bir shift register ile sekiz lambada gösterir. Çalıştır'a bas. Seri monitör "patterns in the list: 8" yazdırır, sonra çubuk teker teker lambaları doldurdukça "step 0 = 1", "step 1 = 11" ve "step 7 = 11111111"e kadar gider. Her adım listedeki bir elemandır.

Aşağıda bir dizinin nasıl yapılacağı ve sayılacağı, ilk elemanın neden 0 numara olduğu ve en çok zaman yiyen iki hata var: sonun ötesini okumak veya yazmak, ve bir fonksiyona dizinin ne kadar büyük olduğunu sormak.

Adım adım sürümünü mü istersin? "A loop over a list" dersi bunu kontrol noktalarıyla anlatıyor.

Dersi aç

Bir tane yap ve sıfırdan say

Tipi, ismi, köşeli parantezleri ve süslü parantez içindeki değerleri yaz. Parantezleri boş bırak, derleyici değerleri senin için sayar. Elemanlar 0'dan numaralanır, yani sekizlik bir dizide PATTERNS[0]'dan PATTERNS[7]'e vardır ve PATTERNS[8] yoktur.

You can also give the size and fill it in later: int readings[10]; makes ten ints. A global array like that starts as all zeros. One made inside a function starts with whatever was in memory, so fill it before you read it.

firmware/uno/examples/cpparray (yukarıda çalışan liste ve döngü)
const byte PATTERNS[] = {
  0b00000001,
  0b00000011,
  0b00000111,
  0b00001111,
  0b00011111,
  0b00111111,
  0b01111111,
  0b11111111,
};

const int COUNT = (int)(sizeof(PATTERNS) / sizeof(PATTERNS[0]));

Kaç tane: sizeof

sizeof bir şeyin boyutunu bayt cinsinden verir, eleman sayısını değil. Yani sayı, tüm dizinin boyutunun bir elemanın boyutuna bölünmesidir. Uno'da beş int için sizeof(scores) 10 bastı, çünkü orada int 2 bayttır. Aynı kod bir ESP32-C3'te 20 bastı, çünkü orada int 4 bayttır. Bir elemanın boyutuna bölününce ikisi de 5 dedi.

Sayıyı bu yolla hesapla, 8'i elle yazma. Yukarıdaki listeye dokuzuncu deseni ekle ve Çalıştır'a bas: ilk satır "patterns in the list: 9" olur, döngü dokuz adım atar ve listeden başka hiçbir şeye dokunmadın.

Bayt cinsinden boyut ve sayı
int scores[5] = {10, 20, 30, 40, 50};

void setup() {
  Serial.begin(9600);
  Serial.println(sizeof(scores));
  Serial.println(sizeof(scores) / sizeof(scores[0]));
}

void loop() {
}

Bu kodu düzenleyicide açSadece kod: düzenleyici, kartı ve koddan okuyabildiği parçaları yerleştirir.

Bir pin dizisi

Bir Arduino'daki en kullanışlı dizi bir pin listesidir. Pin numaralarını bir diziye koy, tek bir döngü hepsini kurar, bir başkası sırayla yakar. Aşağıdaki kod kod tezgahının üç lambasında (pin 13, 12 ve 11) çalışır ve sırayla "pin 13 on", "pin 12 on" ve "pin 11 on" bastı. Listeye bir pin ekle, bir LED'i daha kabzola ve o da katılır.

Arrays of text work the same way. const char *names[] = {"red", "yellow", "green"}; is a list of three words, and names[1] is "yellow". The random numbers page uses one to make a magic eight ball.

Bir dizi satır da tutabilir. const byte GRID[2][3] = {{1, 2, 3}, {4, 5, 6}}; üçlü iki satırdır, GRID[1][0] 4 bastı ve sizeof(GRID) 6 bastı: üç baytlık iki satır. Birbirinin içinde iki for döngüsü her elemanı gezer; bir kod LED matrisinin noktalarını veya bir tuş takımının tuşlarını böyle tutar.

Bir pin listesi
const int LAMPS[] = {13, 12, 11};
const int COUNT = sizeof(LAMPS) / sizeof(LAMPS[0]);

void setup() {
  Serial.begin(9600);
  for (int i = 0; i < COUNT; i++) {
    pinMode(LAMPS[i], OUTPUT);
  }
}

void loop() {
  for (int i = 0; i < COUNT; i++) {
    digitalWrite(LAMPS[i], HIGH);
    Serial.print("pin ");
    Serial.print(LAMPS[i]);
    Serial.println(" on");
    delay(300);
    digitalWrite(LAMPS[i], LOW);
  }
}

Bu kodu düzenleyicide açSadece kod: düzenleyici, kartı ve koddan okuyabildiği parçaları yerleştirir.

Sonun ötesi: hata yok, yanlış yanıtlar

Nothing checks an index while the sketch runs. Ask for entry 5 of a five-entry array and the board does not stop or complain; it reads whatever two bytes come next in memory. Our a[5] printed 280, a number that was never in the list. The build tab did warn about that one, because the 5 was written right there in the code: array index 5 is past the end of the array (that has type 'int[5]').

Sondan sonrasına yazmak daha da kötüdür ve genellikle hiç uyarı vermez, çünkü indeks bir döngü sayacıdır. Beş elemanlı bir diziyi i <= 5 yazan bir döngüyle doldurduğumuzda, hemen sonraki satırda tanımlanan other adlı değişken 99'dan 0'a değişti. Hiçbir şey yazdırılmadı ve hiçbir şey çökmedi. Bunu yapan bir kod tamamen başka bir yerde yanlış gider, bu yüzden bu hatayı bulmak çok zordur. Her seferinde sayaç karşısında < kullan.

Sondan bir sonraki
int a[5] = {10, 20, 30, 40, 50};
int other = 99;

void setup() {
  Serial.begin(9600);
  for (int i = 0; i <= 5; i++) a[i] = 0;
  Serial.println(other);
}

void loop() {
}

Bu kodu düzenleyicide açSadece kod: düzenleyici, kartı ve koddan okuyabildiği parçaları yerleştirir.

Bir diziyi bir fonksiyona geçirmek

Bir fonksiyona verilen dizi, listenin bir kopyası olarak değil, ilk elemanının adresi olarak gelir. Bunun iki sonucu var. Fonksiyon, çağıranın dizisini değiştirebilir, ki bu genellikle istediğiniz şeydir. Ve fonksiyonun içinde sizeof artık dizinin uzunluğunu bilmez: setup() içinde 10 bayta ölçen aynı scores, bir fonksiyonun içinde 2'ye ölçtü; bir Uno'da bir adresin boyutu. Derleme sekmesi şu uyarıyı verdi: sizeof on array function parameter will return size of 'int *' instead of 'int[]'.

Bu yüzden sayıyı diziyle birlikte geçirin, örneğin average(scores, 5) gibi, ya da dizinin oluşturulduğu yerde sizeof ile hesaplayıp onu geçirin. Arabellek alan her Arduino kütüphanesi bunu bu şekilde yapar.

Bu devreyi düzenleyicide aç. Arduino Uno: bir dizide sekiz desen, sekiz lamba üzerinde, bu sayfanın üstünde çalıştığı gibi kablolandı. Bir parçayı ya da değeri değiştir ve yeniden çalıştır.

Sorular

Arduino dizileri 0 ile mi 1 ile mi başlar?

0 ile. Bir dizinin ilk elemanı name[0] ve sekiz elemanlı bir dizinin sonuncusu name[7]'dir. Dizi üzerinde bir döngü şöyle yazılır: for (int i = 0; i < 8; i++).

Arduino'da bir dizinin uzunluğunu nasıl bulurum?

Bayt cinsinden boyutunu bir elemanın boyutuna bölün: sizeof(list) / sizeof(list[0]). Bu yalnızca dizinin tanımlandığı yerde çalışır; diziye verilmiş bir fonksiyonun içinde sizeof bunun yerine bir adresin boyutunu verir.

Bir dizinin boyutunu değiştirebilir miyim?

Hayır. Boyutu, kod derlenirken sabitlenir. İhtiyacınız olabilecek kadar büyük yapın ve kaç elemanın kullanımda olduğunu ayrı bir sayı olarak tutun.

Bir dizinin sonunun ötesine geçersem ne olur?

Hiçbir şey bunu engellemez. Sondan sonrasını okumak bellekte ondan sonra ne varsa onu verir, sondan sonrasına yazmak ise başka bir değişkeni değiştirir. Testimizde, bir eleman fazladan yazmak komşu bir değişkeni hatasız bir şekilde 99'dan 0'a çevirdi.

Bir dizi metin tutabilir mi?

Yes. const char *names[] = {"red", "yellow", "green"}; is an array of three strings, and names[0] is "red". A single piece of text is itself an array of char, ending in a zero byte.

Kaynaklar

Bu sayfadaki bilgiler nereden geliyor

Bunu gerçekten kur

Düzenleyiciyi aç, bir değeri değiştir ve sayının onunla birlikte değiştiğini izle. Kurulacak bir şey yok, hesaba da gerek yok.