O editor

Blynk, simulado

Rode um sketch Blynk sem mudanças num ESP8266, ESP32 ou Pico W, e observe e defina seus pinos virtuais no painel Cloud.

O servidor Blynk é simulado. Nada chega a blynk.cloud, e não há conta, app ou template Blynk por trás dele. O que é fiel é o código Arduino que você escreve: Blynk.begin(), Blynk.virtualWrite(), BLYNK_WRITE e BlynkTimer se comportam como a biblioteca Blynk numa placa real, então o sketch que você testa aqui é o sketch que você gravará depois.

Os cabeçalhos

  • ESP8266 (NodeMCU, D1 mini): #include <BlynkSimpleEsp8266.h>
  • Placas ESP32 (ESP32, ESP32-C3, ESP32-C6, ESP32-S3 e as placas construídas sobre elas): #include <BlynkSimpleEsp32.h>
  • Pico W e UNO R4 WiFi: #include <BlynkSimpleWifi.h>

Cada um verifica a placa como o da própria Blynk faz: o cabeçalho do ESP8266 numa ESP32 para com Este código foi feito para rodar na plataforma ESP8266!

Um monitor de luz

Um LDR de 3V3 para A0, um resistor de 10k de A0 para GND, e um LED com um resistor de 220 ohms no D1:

#define BLYNK_TEMPLATE_ID "TMPLxxxxxx"
#define BLYNK_TEMPLATE_NAME "Light Intensity Monitor"
#define BLYNK_AUTH_TOKEN "YourAuthToken"
#define BLYNK_PRINT Serial

#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>

BlynkTimer timer;

BLYNK_WRITE(V1) {
  digitalWrite(D1, param.asInt());
}

void sendLight() {
  Blynk.virtualWrite(V0, analogRead(A0));
}

void setup() {
  Serial.begin(115200);
  pinMode(D1, OUTPUT);
  Blynk.begin(BLYNK_AUTH_TOKEN, "Mokxi-Lab", "breadboard");
  timer.setInterval(1000L, sendLight);
}

void loop() {
  Blynk.run();
  timer.run();
}

The network name and password are the board's wifiSsid and wifiPassword properties, as in WiFi, simulado. Os exemplos da biblioteca no editor têm este pronto para rodar.

A seção Blynk do painel Cloud

Abra Cloud ao lado de Serial enquanto o sketch roda. Quando a placa faz login, aparece uma seção Blynk:

  • se o dispositivo está online, o nome e o ID do template, e o começo do seu token (exibido, nunca conferido);
  • uma linha por pino virtual que o sketch escreveu ou para o qual tem um BLYNK_WRITE, com o valor, quem definiu e quando. V0 acima mostra o nível de luz, e mover o controle do LDR muda isso no próximo envio;
  • 0, 1 e uma caixa com Enviar em cada linha, que é o interruptor ou o slider do app Blynk: envie 1 para V1 e o BLYNK_WRITE(V1) do sketch acende o LED. Qualquer pino envia para um pino que ainda não tem linha;
  • os últimos eventos de Blynk.logEvent().

O que é real e o que não é

Real, do jeito que a biblioteca Blynk faz:

  • Blynk.begin() espera até a placa estar na rede e com login feito;
  • BLYNK_WRITE roda dentro de Blynk.run(), então um loop() que para de chamá-lo para de ouvir o painel, como uma placa real para de ouvir o app;
  • BLYNK_CONNECTED roda a cada login, e Blynk.syncVirtual() ou syncAll() ali traz de volta os últimos valores do servidor para o BLYNK_WRITE;
  • uma escrita com a placa offline é descartada, e uma placa que sai da rede faz login de novo cinco segundos depois de voltar;
  • um float é enviado com três decimais e um double com sete;
  • param.asInt(), asFloat(), asStr() e param[1] para um pino com vários valores; WidgetLED, WidgetTerminal, WidgetLCD e Blynk.setProperty() (sketches antigos que incluem WidgetLCD.h, WidgetLED.h, WidgetTerminal.h ou BlynkWidgets.h pelo nome também compilam);
  • Blynk.notify(), Blynk.email() e Blynk.tweet() da Blynk 0.6, de tutoriais antigos, aparecem como eventos: nada é enviado por notificação, e-mail ou post.

Não simulado:

  • o app Blynk, o painel web e a conta: o painel Cloud faz esse papel;
  • o widget de LCD não é desenhado: seu pino mostra a última mensagem que a biblioteca enviou, clr ou p, x, y, texto (então lcd.print(4, 1, "World") lê p, 4, 1, World);
  • BLYNK_APP_CONNECTED, que compila e nunca roda, já que nada abre um app (BLYNK_READ saiu da Blynk 1.4.0: um sketch que o usa recebe um erro de compilação dizendo para enviar o valor com Blynk.virtualWrite() a partir de um BlynkTimer);
  • Blynk.Edgent (BlynkEdgent.h), atualizações de firmware over the air e os cabeçalhos _SSL.