Belajar

Sensor radar gerak RCWL-0516 di sebuah Arduino

Pemula

Atau lihat semua pelajaran.

  • 526komponen di meja kerja
  • 46board sedang berjalan
  • 1.00xwaktu nyata, di semua board
Arduino Uno: lampu radar RCWL-0516live0.000 s 0.00x
Klik untuk membukanya di editor
RCWL-0516 di pin 2 menyalakan LED di pin 13, pada ATmega328P tersimulasi. Klik sensor untuk memulai dan menghentikan gerakan.

RCWL-0516 adalah sensor gerak yang menggunakan radar alih-alih panas. Pemancar 3,2 GHz kecil di board mengirim sinyal, dan benda yang bergerak menggeser frekuensi gema sedikit, itu efek Doppler. Chip di board mengubahnya menjadi satu keluaran digital: tinggi selama ada yang bergerak. Harganya kira-kira sama dengan sensor PIR dan bisa menembus plastik, kaca, dan dinding tipis.

Rangkaian di atas adalah Uno dengan RCWL-0516 di pin 2, menyalakan LED bawaan Uno di pin 13 selama ada yang bergerak. Klik sensor untuk memulai gerakan dan klik lagi untuk menghentikannya, dan serial monitor mencetak kapan ruangan menjadi ramai dan kapan kembali sepi. Semuanya berjalan di browser-mu dengan sketch di bawah.

Yang kamu butuhkan

  • Arduino Uno
  • Sebuah modul RCWL-0516
  • Tiga kabel jumper

Pengkabelan

Komponen dan pinDisambung keCatatan
RCWL-0516 VIN5 VMenerima 4 sampai 28 V
RCWL-0516 GNDGND
RCWL-0516 OUTPin 2Tinggi di 3,3 V selama mendeteksi gerakan
3V3 dan CDSTidak tersambung3V3 adalah keluaran; CDS untuk sensor cahaya

Satu pin, tanpa library

OUT naik tinggi, ke 3,3 V, begitu board mendeteksi gerakan. 3,3 V jauh di atas ambang yang dianggap HIGH oleh Uno 5 V, jadi tersambung langsung ke pin tanpa level shifter. Sketch membacanya dengan digitalRead(), menyalinnya ke LED di pin 13, dan mencetak satu baris setiap kali berubah.

OUT tetap tinggi selama gerakan berlangsung, dan selama dua detik setelah berhenti. Klik sensor, tunggu setengah detik dan klik lagi: serial monitor menampilkan "Movement", lalu "Clear after 2505 ms", setengah detik gerakan ditambah dua detik tahanan.

Sketch lampu radar, versi ringkas
const int SENSOR_PIN = 2;
const int LAMP_PIN = 13;

bool busy = false;
unsigned long since = 0;

void setup() {
  Serial.begin(9600);
  pinMode(SENSOR_PIN, INPUT);
  pinMode(LAMP_PIN, OUTPUT);
  Serial.println("Radar ready");
}

void loop() {
  bool seen = digitalRead(SENSOR_PIN) == HIGH;
  digitalWrite(LAMP_PIN, seen ? HIGH : LOW);
  if (seen != busy) {
    busy = seen;
    unsigned long now = millis();
    if (busy) {
      Serial.println("Movement");
    } else {
      Serial.print("Clear after ");
      Serial.print(now - since);
      Serial.println(" ms");
    }
    since = now;
  }
  delay(20);
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Radar atau PIR?

Sensor PIR seperti HC-SR501 mendeteksi panas tubuh yang bergerak melintas di depannya. RCWL-0516 mendeteksi apa pun yang bergerak, panas atau tidak, bahkan menembus kotak plastik dan dinding tipis. PIR juga punya waktu mati setelah tiap pemicuan, sekitar 2,5 detik, saat ia sama sekali tidak bisa terpicu. RCWL-0516 tidak punya itu.

Kamu bisa melihatnya di sini. Bergerak sebentar, berhenti sedetik, lalu bergerak lagi sebelum dua detik habis: waktu tahan dimulai ulang, dan kamu dapat satu "Clear after" sekitar 3,6 detik alih-alih dua alarm terpisah. Tutorial PIR menjelaskan waktu tahan dan waktu blokir pada PIR.

Melihat menembus benda tidak selalu bagus. Sensor radar di lorong bisa terpicu oleh orang di ruangan sebelah, atau oleh kipas atau gorden. PIR pilihan yang lebih baik kalau kamu hanya ingin mendeteksi ruangan di depannya.

Waktu tahan dan pin CDS

Tahanan dua detik diatur oleh komponen di board. Pada modul sungguhan, pad di belakang bertuliskan C-TM, R-GN dan R-CDS biasa dipakai untuk memperpanjang tahanan, memperpendek jangkauan, dan menambah sensor cahaya. Di Mokxi, tahanannya adalah properti hold pada sensor: set ke 5 dan gerakan setengah detik akan mencetak "Clear after 5309 ms".

CDS dimaksudkan untuk LDR (resistor peka cahaya), supaya sensor hanya bekerja dalam gelap. Kalau ditarik turun di bawah sekitar 0,7 V, sensor mati. Sambungkan kabel CDS ke GND di rangkaian ini dan mengklik sensor tidak bereaksi apa-apa. Biarkan tidak tersambung untuk sensor yang selalu aktif.

Kesalahan umum

Menyalakannya dari pin 3V3. VIN butuh setidaknya 4 V. Pin 3V3 pada modul adalah output regulatornya sendiri, bukan input.

Memasangnya di belakang logam. Radar tidak menembus logam, jadi kotak logam membuatnya buta.

Mengira ia mengabaikan ruangan sebelah. Ia bisa menembus dinding dan pintu.

CDS tak sengaja terhubung ke GND, yang mematikan sensor.

Dua modul berdekatan. Sinyalnya bisa saling mengganggu dan memicu satu sama lain. Mokxi tidak memodelkan itu, atau pemicuan palsu dari kipas dan getaran, jadi uji modul sungguhan di tempatnya.

Buka rangkaian ini di editor. Arduino Uno: lampu radar RCWL-0516, dengan kabel seperti rangkaian yang berjalan di bagian atas halaman ini. Ubah komponen atau nilainya dan jalankan lagi.

Buka rangkaian ini

Pertanyaan

Bagaimana cara menyambungkan RCWL-0516 ke Arduino?

VIN ke 5 V, GND ke GND, dan OUT ke pin digital mana pun. Baca OUT dengan digitalRead(); ia HIGH selama sensor melihat gerakan dan sekitar dua detik setelahnya.

Apakah RCWL-0516 butuh library?

Tidak. Ia punya satu output digital, jadi digitalRead() sudah cukup sebagai kodenya.

Berapa jangkauan RCWL-0516?

Sekitar 5 sampai 7 meter, menembus plastik dan dinding tipis. Mokxi memodelkan gerakan hanya sebagai dalam jangkauan atau tidak, jadi jangkauan bukan hal yang bisa kamu uji di sini.

Apakah RCWL-0516 lebih baik dari sensor PIR?

Itu berbeda. Ia melihat gerakan apa pun, menembus selubung, tanpa waktu mati, tapi ia juga menembus dinding dan terpicu oleh kipas. PIR hanya melihat tubuh panas di depannya.

Rakit versi nyatanya

Buka editor, ubah sebuah nilai, dan lihat angkanya ikut berubah. Tidak ada yang perlu dipasang, dan tidak perlu akun.