تعلّم

عدّاد أزرار Arduino يعد كل ضغطة مرة واحدة

متوسط

أو تصفّح كل الدروس.

  • 526قطعة على المنضدة
  • 46لوحة تعمل الآن
  • 1.00xزمن حقيقي، على كل لوحة
Arduino Uno: لوحة نتائج تعد ضغطات الأزرارمباشر0.000 s 0.00x
اضغط «تشغيل»، ثم اضغط زر المضيف أو زر الضيف
اضغط زر المضيف أو الضيف لكسب نقطة، واستمر في الضغط على أحدهما لثانية واحدة لاسترجاع نقطة.

لعد ضغطات الزر، عُد لحظة نزول الزر فقط، لا كل مرة يجده فيها loop() مضغوطًا. احفظ حالة الزر في المرة السابقة؛ فإذا كان مضغوطًا الآن ومرتفعًا قبل ذلك، فهذه ضغطة واحدة. ثم انتظر بضع أجزاء من الألف من الثانية حتى يهدأ ارتداد التلامس قبل تصديق أي تغيير، وإلا عُدّت الضغطة الواحدة عدة مرات.

الدائرة أعلاه لوحة نتائج على لوحة Uno: شاشة MAX7219 بثمانية أرقام، نتيجة المضيف على اليسار، وساعة المباراة في الوسط، ونتيجة الضيف على اليمين. اضغط «تشغيل»، ثم زر المضيف أو الضيف، فترتفع تلك النتيجة بمقدار واحد. استمر في الضغط على زر لثانية واحدة تعود النتيجة إلى الوراء واحدًا، لنقطة مُنحت بالخطأ. الزر الثالث يشغّل الساعة ويوقفها.

أدناه العدّاد مبنيًّا من جديد بدءًا من الخطأ الذي يقع فيه الجميع أولًا، مع النتائج التي أعطتها كل نسخة لنفس الضغطتين على لوحة Uno، وضغطة طويلة تصفّر العدّاد، وزرين يعدّان صعودًا وهبوطًا.

العدّ أثناء الاستمرار في الضغط

المحاولة الأولى تضيف واحدًا كلما قرأ الطرف قيمة LOW. يعمل loop() عشرات آلاف المرات في الثانية، لذا عدّت الضغطة الواحدة 22976 خلال أول 200 ms من الاستمرار بها، وكانت القراءة التالية ‎-30754: المتغيّر int لا يتجاوز 32767، فالتف إلى الأعداد السالبة. الزر موصّل من الطرف 2 إلى GND، مع INPUT_PULLUP، فالضغط يعني LOW.

يعد كل دورة لا كل ضغطة
int count = 0;

void setup() {
  Serial.begin(9600);
  pinMode(2, INPUT_PULLUP);
}

void loop() {
  if (digitalRead(2) == LOW) {
    count++;
  }
  static unsigned long last = 0;
  if (millis() - last >= 500) {
    last = millis();
    Serial.println(count);
  }
}

افتح هذا الكود في المحررالكود وحده: يضع المحرر اللوحة والقطع التي يستطيع قراءتها من الكود.

كشف تغيّر الحالة

احفظ القراءة السابقة وعُد التغيّر من المرتفع إلى المضغوط فقط. هذا هو كشف تغيّر الحالة، أو كشف الحافة. عدّت الضغطتان الآن 10 بدل عشرات الآلاف، لكنها ليست 2 بعد.

الـ 8 الأخرى ارتداد تلامس. تلامسات الزر المعدنية تتباعد ثم تتلامس مرات عدة خلال أول أجزاء من الألف من الثانية من الضغط ومن الترك، والكود سريع بما يكفي ليرى كل تلامس كضغطة جديدة. زر Mokxi يرتد مثل الزر الحقيقي، ولهذا يظهر الأمر هنا.

يعد كل تغيّر، والارتداد أيضًا
const int BUTTON = 2;
int count = 0;
bool wasDown = false;

void setup() {
  Serial.begin(9600);
  pinMode(BUTTON, INPUT_PULLUP);
}

void loop() {
  bool down = digitalRead(BUTTON) == LOW;
  if (down && !wasDown) {
    count++;
    Serial.print("presses: ");
    Serial.println(count);
  }
  wasDown = down;
}

افتح هذا الكود في المحررالكود وحده: يضع المحرر اللوحة والقطع التي يستطيع قراءتها من الكود.

مع منع الارتداد: ضغطة واحدة، عدّة واحدة

لا تصدّق الزر إلا بعد أن يعطي نفس القراءة مدةً من الوقت. الكود أدناه يلاحظ متى تغيّرت القراءة آخر مرة ولا يقبل الحالة الجديدة إلا بعد 20 ms دون تغيّر. الضغطتان نفساهما طبعتا "presses: 1" ثم "presses: 2". لا حاجة إلى delay()، فيستمر باقي loop() في العمل.

عدّاد ضغطات مع منع ارتداد مدته 20 ms
const int BUTTON = 2;
int count = 0;
bool stable = false;
bool lastRead = false;
unsigned long changedAt = 0;

void setup() {
  Serial.begin(9600);
  pinMode(BUTTON, INPUT_PULLUP);
}

void loop() {
  bool reading = digitalRead(BUTTON) == LOW;
  if (reading != lastRead) {
    changedAt = millis();
    lastRead = reading;
  }
  if (millis() - changedAt > 20 && reading != stable) {
    stable = reading;
    if (stable) {
      count++;
      Serial.print("presses: ");
      Serial.println(count);
    }
  }
}

افتح هذا الكود في المحررالكود وحده: يضع المحرر اللوحة والقطع التي يستطيع قراءتها من الكود.

ضغطة طويلة تصفّر العدّاد

للتمييز بين ضغطة واستمرار، لاحظ متى نزل الزر وعُد عند الترك بدلًا من ذلك. إذا استمر الضغط ثانية كاملة، فنفّذ مهمة الاستمرار وتخطَّ العدّ. بضغطتين قصيرتين ثم ضغطة طويلة، طبعت نسخة من الكود أعلاه مبنية بهذه الطريقة "presses: 1" و "presses: 2" و "held: back to 0".

لوحة النتائج العاملة أعلاه تفعل هذا بالضبط في دالتها check(): ترك بعد 20 ms على الأقل يُعد ضغطة، واستمرار 1000 ms يُعد استمرارًا يسترجع نقطة.

firmware/uno/examples/scoreboard (اضغط أو استمر بالضغط، من الكود العامل أعلاه)
uint8_t check(Button &b) {
  bool down = digitalRead(b.pin) == LOW;
  unsigned long now = millis();
  uint8_t event = 0;
  if (down && !b.down) {
    b.since = now;
    b.held = false;
  } else if (down && !b.held && now - b.since >= 1000) {
    b.held = true;
    event = 2;
  } else if (!down && b.down && !b.held && now - b.since >= 20) {
    event = 1;
  }
  b.down = down;
  return event;
}

لماذا لا نعدّ بمقاطعة؟

تشغّل attachInterrupt() على الطرف 2 دالةً لحظة تغيّر الطرف، وهذا يبدو مصنوعًا للعدّ. لكنه للأزرار أداة خاطئة: فالمقاطعة ترى كل ارتداد أيضًا، فتعدّ أكثر من اللازم تمامًا كما فعل كود كشف تغيّر الحالة، ومنع الارتداد داخل معالج المقاطعة يعني التوقيت بـ millis() هناك، وهو أمر مزعج. تستحق المقاطعة مكانها مع النبضات السريعة أو القصيرة جدًا بحيث يعجز loop() عن التقاطها، مثل حساس تدفق أو مرمّز عجلة، وفي صفحة المقاطعات عدّاد لتلك الاستخدامات.

أقصر ضغطة تستغرق عشرات الملّي ثانية، ودالة loop() تدور آلاف المرات خلال ذلك، لذا فإن قراءة الطرف داخل loop() لا تفوّت أي ضغطة أبدًا، ما دام لا شيء داخل loop() يعطّل التنفيذ لفترة طويلة. وجود delay(1000) في مكان آخر من الكود هو ما يجعل العدّاد يفوّت الضغطات.

الحفاظ على العدد بعد إعادة التشغيل

المتغير يبدأ من 0 من جديد في كل مرة تعاد فيها تشغيل اللوحة أو ينقطع عنها التيار. للحفاظ على العدد، احفظه بـ EEPROM.put(0, count) عند تغيّره واقرأه مجددًا بـ EEPROM.get(0, count) في setup(). تتلف ذاكرة EEPROM بعد نحو 100,000 عملية كتابة إلى العنوان نفسه، لذا مع عدّاد يتغيّر كثيرًا، احفظ القيمة كل عدد معيّن من الضغطات أو عند طلب زر لذلك، لا مع كل ضغطة.

الزيادة والنقصان بزرّين

زرّان وحالتان محفوظتان. الكود أدناه يعدّ صاعدًا على الطرف 2 ونازلًا على الطرف 3 ويبقي العدد بين 0 و99 باستخدام constrain(). ضغطة نزول وضغطتا صعود وضغطة نزول طبعا 0 و1 و2 و1: الضغطة الأولى لم تستطع النزول تحت 0. تأخير قصير delay(20) في نهاية loop() هو أبسط حل للاهتزاز عندما لا يوجد شيء آخر يفعله الكود.

من هنا، اعرض العدد على شاشة: صفحات الشاشة ذات الأجزاء السبعة وTM1637 والشاشة الكريستالية تطبع كلها رقمًا. على لوحة Uno، يعدّ المتغير int حتى 32767؛ استخدم unsigned long للمزيد.

العدّ صاعدًا ونازلًا
const int UP = 2;
const int DOWN = 3;
int count = 0;
bool upWas = false;
bool downWas = false;

void setup() {
  Serial.begin(9600);
  pinMode(UP, INPUT_PULLUP);
  pinMode(DOWN, INPUT_PULLUP);
}

void loop() {
  bool up = digitalRead(UP) == LOW;
  bool down = digitalRead(DOWN) == LOW;
  if (up && !upWas) count++;
  if (down && !downWas) count--;
  if ((up && !upWas) || (down && !downWas)) {
    count = constrain(count, 0, 99);
    Serial.println(count);
  }
  upWas = up;
  downWas = down;
  delay(20);
}

افتح هذا الكود في المحررالكود وحده: يضع المحرر اللوحة والقطع التي يستطيع قراءتها من الكود.

افتح هذه الدائرة في المحرر. لوحة Arduino Uno: لوحة نتائج تعدّ ضغطات الزر، موصّلة كما تعمل في أعلى هذه الصفحة. غيّر قطعة أو قيمة وشغّلها من جديد.

افتح الدائرة

الأسئلة

كيف أعدّ ضغطات الزر على Arduino؟

تذكّر حالة الزر من آخر دورة لـ loop() وأضف واحدًا فقط عندما تتغيّر من مرفوع إلى مضغوط. عالج الاهتزاز، وإلا فستُحسب الضغطة الواحدة عدة مرات.

لماذا يعدّ عدّاد الزر أكثر من مرة في الضغطة الواحدة؟

اهتزاز التلامس: يفتح الزر التلامس ويغلقه عدة مرات في أول ملّي ثوانٍ قليلة. اقبل التغيير فقط بعد أن تثبت القراءة لنحو 20 ms.

لماذا يصبح العدّاد على Arduino سالبًا؟

لأنه يعدّ كل دورة من loop() أثناء إبقاء الزر مضغوطًا، والمتغير int يلتف من 32767 إلى -32768. عُدّ التغيّر من مرفوع إلى مضغوط بدلًا من ذلك.

كيف أكشف الضغطة الطويلة على زر في Arduino؟

احفظ millis() عندما ينخفض الزر. إذا كان لا يزال مضغوطًا بعد ثانية، فهي ضغطة طويلة؛ وإذا ارتفع قبل ذلك، فكانت قصيرة.

المصادر

من أين جاءت الحقائق في هذه الصفحة

ابنِ هذا على أرض الواقع

افتح المحرر وغيّر قيمة وشاهد الرقم يتحرك معها. لا شيء لتثبّته ولا حاجة إلى حساب.