Belajar

Arduino strtok: memecah teks dan mengurai perintah serial

Atau lihat semua pelajaran.

  • 526komponen di meja kerja
  • 46board sedang berjalan
  • 1.00xwaktu nyata, di semua board
Arduino Uno: menampilkan kembali apa yang dikirim Serial Monitorlive0.000 s 0.00x
Klik untuk membukanya di editor
Ketik sebuah kata lalu tekan Enter: tiap byte kembali di barisnya sendiri, baris baru paling akhir.

strtok() memecah sebuah array char menjadi potongan-potongan pada karakter yang kamu tentukan, misalnya koma atau spasi. Panggilan pertama menerima array-nya, tiap panggilan berikutnya menerima NULL dan lanjut dari tempat panggilan terakhir berhenti, dan ia mengembalikan NULL jika tidak ada lagi yang tersisa. Fungsi ini bekerja pada teks C biasa, bukan String, jadi ia menggunakan sedikit memori dan cocok untuk baris pendek yang dikirim sensor atau Serial Monitor.

Rangkaian di atas adalah sebuah Uno yang menampilkan kembali apa yang kamu ketik, satu byte dalam satu waktu. Setelah mengetik "on" dan Enter, ia mencetak "you typed: o (0x6F)", "you typed: n (0x6E)" dan "you typed: <newline>". Byte datang satu per satu, jadi sketch mengumpulkannya dulu menjadi satu baris, baru kemudian memecahnya.

Di bawah ini: cara memecah nilai yang dipisahkan koma menjadi angka, apa yang strtok lakukan pada array-mu, kenapa String perlu disalin, parser perintah yang mengendalikan LED, dan strtok_r untuk pemecahan di dalam pemecahan. Untuk memecah String dengan indexOf() dan substring(), lihat halaman String.

Mau versi langkah demi langkah? Pelajaran "Taking commands" membahas ini dengan checkpoint.

Buka pelajaran

Memecah nilai yang dipisahkan koma menjadi array

Panggil strtok(line, ",") sekali untuk potongan pertama, lalu strtok(NULL, ",") dalam loop sampai mengembalikan NULL, dan ubah tiap potongan dengan atof() untuk desimal atau atoi() untuk bilangan bulat. Sketch di bawah mencetak "3 values", lalu "21.50", "48.00" dan "1013.00".

Berhenti pada ukuran array-mu, seperti yang dilakukan count < 3: baris dengan koma lebih banyak dari yang kamu duga tidak boleh menulis melewati akhir array.

The last line shows what strtok leaves behind. It printed "line is now: 21.5". strtok writes a zero over each comma it finds, so the array now ends after the first piece. Copy the line first if you need it again.

Tiga angka dari satu baris
void setup() {
  Serial.begin(9600);
  char line[] = "21.5,48,1013";
  float values[3];
  int count = 0;

  char *piece = strtok(line, ",");
  while (piece != NULL && count < 3) {
    values[count] = atof(piece);
    count++;
    piece = strtok(NULL, ",");
  }

  Serial.print(count);
  Serial.println(" values");
  for (int i = 0; i < count; i++) {
    Serial.println(values[i]);
  }
  Serial.print("line is now: ");
  Serial.println(line);
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Field kosong hilang

strtok memperlakukan beberapa koma berurutan sebagai satu, jadi field kosong dilewati, bukan dikembalikan kosong. Sketch yang sama dengan "5,,7" mencetak "2 values", 5.00 dan 7.00: angka 7 pindah ke tempat kedua. Jika sebuah field bisa kosong, periksa jumlahnya, atau kirimkan 0 daripada tidak mengirim apa-apa.

strtok butuh array char, bukan String

strtok changes the text it splits, so it takes a char *. Giving it a String’s text with strtok(line.c_str(), ",") stopped the build with no matching function for call to 'strtok', and the note says 1st argument ('const char *') would lose const qualifier: c_str() is read only. The Arduino IDE’s GCC says invalid conversion from 'const char*' to 'char*'.

Salin dulu String ke dalam array char dengan toCharArray(). Sketch di bawah mencetak "21.5" dan "48". String dalam tanda kutip yang ditulis langsung di dalam pemanggilan, strtok("21.5,48", ","), hanya mendapat peringatan, ISO C++11 does not allow conversion from string literal to 'char *', dan peringatan GCC adalah ISO C++ forbids converting a string constant to 'char*'. Itu berjalan di sini dan mencetak 21.5, tapi jangan mengandalkannya: teks dalam tanda kutip memang seharusnya tetap apa adanya, sedangkan strtok menulis ke dalamnya.

String yang disalin ke array char
void setup() {
  Serial.begin(9600);
  String line = "21.5,48";
  char buf[32];
  line.toCharArray(buf, sizeof(buf));
  char *piece = strtok(buf, ",");
  while (piece != NULL) {
    Serial.println(piece);
    piece = strtok(NULL, ",");
  }
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Parser perintah serial

Sketch di bawah mengumpulkan byte ke dalam buffer 32 byte sampai baris baru, lalu memecah baris itu pada spasi menjadi satu perintah dan dua argumen, dan membandingkan perintahnya dengan strcmp(). Ia mengerti "led 13 on", "led 12 off" dan "blink 11 3". Apa pun yang lain tetap mendapat jawaban, jadi salah ketik tidak pernah diam saja.

Kami mengetik lima baris: led 13 on, led 12 on, led 13 off, blink 11 3 dan hello. Ia mencetak "pin 13 on", "pin 12 on", "pin 13 off", "blinked 3 times" dan "unknown: hello", dan meninggalkan LED pada pin 12 menyala. Pemeriksaan len < sizeof(buf) - 1 membuang apa pun yang melebihi 31 karakter alih-alih menulis melewati buffer, dan uji \r membuatnya bekerja dengan akhir baris apa pun yang dikirim monitor. Untuk menerima koma selain spasi antara kata-kata, berikan strtok " ," sebagai pemisahnya alih-alih " ".

Perintah untuk tiga LED
char buf[32];
byte len = 0;

void setup() {
  Serial.begin(9600);
  pinMode(13, OUTPUT);
  pinMode(12, OUTPUT);
  pinMode(11, OUTPUT);
  Serial.println("ready");
}

void runCommand(char *line) {
  char *cmd = strtok(line, " ");
  char *arg1 = strtok(NULL, " ");
  char *arg2 = strtok(NULL, " ");
  if (cmd == NULL) return;

  if (strcmp(cmd, "led") == 0 && arg1 && arg2) {
    int pin = atoi(arg1);
    digitalWrite(pin, strcmp(arg2, "on") == 0 ? HIGH : LOW);
    Serial.print("pin ");
    Serial.print(pin);
    Serial.print(" ");
    Serial.println(arg2);
  } else if (strcmp(cmd, "blink") == 0 && arg1 && arg2) {
    int pin = atoi(arg1);
    int times = atoi(arg2);
    for (int i = 0; i < times; i++) {
      digitalWrite(pin, HIGH);
      delay(100);
      digitalWrite(pin, LOW);
      delay(100);
    }
    Serial.print("blinked ");
    Serial.print(times);
    Serial.println(" times");
  } else {
    Serial.print("unknown: ");
    Serial.println(cmd);
  }
}

void loop() {
  while (Serial.available() > 0) {
    char c = Serial.read();
    if (c == '\r') continue;
    if (c == '\n') {
      buf[len] = '\0';
      runCommand(buf);
      len = 0;
    } else if (len < sizeof(buf) - 1) {
      buf[len++] = c;
    }
  }
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Pemecahan di dalam pemecahan: strtok_r

strtok mengingat posisinya dalam satu variabel tersembunyi, jadi ia hanya bisa memproses satu baris dalam satu waktu. Memecah "temp=21;hum=48;lux=310" pada titik koma, dan tiap pasangan pada tanda sama dengan dengan strtok juga, mencetak "temp -> 21" lalu berhenti: panggilan bagian dalam kehilangan posisi panggilan luarnya.

strtok_r menerima posisi sebagai argumen ketiga, jadi tiap level punya posisinya sendiri. Versi di bawah mencetak "temp -> 21", "hum -> 48" dan "lux -> 310". Gunakan strtok_r setiap kali sebuah fungsi yang memecah teks bisa dipanggil dari dalam pemecahan lain.

Pasangan kunci dan nilai dengan strtok_r
void setup() {
  Serial.begin(9600);
  char line[] = "temp=21;hum=48;lux=310";
  char *outer;
  char *pair = strtok_r(line, ";", &outer);
  while (pair != NULL) {
    char *inner;
    char *key = strtok_r(pair, "=", &inner);
    char *value = strtok_r(NULL, "=", &inner);
    Serial.print(key);
    Serial.print(" -> ");
    Serial.println(atoi(value));
    pair = strtok_r(NULL, ";", &outer);
  }
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Buka rangkaian ini di editor. Arduino Uno: menggemakan apa yang dikirim Serial Monitor, dengan kabel seperti saat dijalankan di bagian atas halaman ini. Ubah komponen atau nilainya lalu jalankan lagi.

Pertanyaan

Bagaimana strtok bekerja di Arduino?

The first call, strtok(line, ","), returns the first piece of a char array; each later call, strtok(NULL, ","), returns the next, and NULL means there are no more. It replaces each separator in the array with a zero as it goes.

Bisakah aku memakai strtok dengan String?

Tidak langsung: c_str() hanya bisa dibaca sedangkan strtok menulis ke dalam teksnya, jadi build berhenti. Salin String itu ke array char dengan toCharArray() lalu pecahkan array tersebut.

Kenapa strtok melewatkan field kosongku?

Ia memperlakukan dua pemisah berurutan sebagai satu, jadi "5,,7" menghasilkan dua potongan, bukan tiga. Periksa ada berapa potongan yang kembali, atau kirimkan 0 untuk nilai yang hilang.

Bagaimana cara mem-parse perintah dari Serial Monitor?

Collect bytes into a char array until a newline, end it with a zero, split it at spaces with strtok, and compare the first piece with strcmp(). The parser on this page does it for LED commands.

Apa bedanya strtok dengan strtok_r?

strtok menyimpan posisinya dalam satu variabel tersembunyi, jadi dua pemecahan sekaligus saling mengganggu. strtok_r menerima posisi sebagai argumen, jadi pemecahan di dalam pemecahan bisa bekerja.

Rakit versi nyatanya

Buka editor, ubah sebuah nilai, dan lihat angkanya ikut berubah. Tidak ada yang perlu dipasang, dan tidak perlu akun.