Belajar

Pointer Arduino, pada dua lampu dan fungsi yang membagi dua sebuah delay

Atau lihat semua pelajaran.

  • 526komponen di meja kerja
  • 46board sedang berjalan
  • 1.00xwaktu nyata, di semua board
Arduino Uno: dua lampu, dan delay yang dibagi dua lewat pointerlive0.000 s 0.00x
Klik untuk membukanya di editor
halve(&onMs) mengambil alamat onMs, jadi ia bisa mengubah variabel milik pemanggilnya.

A pointer is a variable that holds the address of another variable. &speed is the address of speed, int *p = &speed; keeps that address in p, and *p goes to the address, so *p = 50; changes speed. On an Uno an address is 2 bytes. Pointers are how a function changes the caller’s variable, and how an array reaches a function at all.

Rangkaian di atas adalah dua lampu di Uno yang waktu kedipnya diubah lewat pointer. Tekan Jalankan. Serial monitor mencetak "onMs before = 400" dan "onMs after = 200", karena halve(&onMs) memberi fungsi itu alamat onMs dan fungsi itu membagi dua isinya. Lalu muncul "sizeof(int*) = 2", "sum of rates = 1500" dan dua laju yang dibaca lewat pointer, 100 dan 400.

Di bawah ini ada & dan *, pointer versus reference, array sebagai pointer, menelusuri string, pointer fungsi dan kesalahannya, masing-masing dijalankan di Uno dengan hasil cetaknya.

Mau versi langkah demi langkah? Pelajaran "Where a thing lives" membahas ini dengan checkpoint.

Buka pelajaran

Dua simbol itu

Dalam deklarasi, * berarti "pointer ke": int *value adalah pointer ke sebuah int. Di tempat lain, *value berarti "int di alamat itu", dan &onMs berarti "alamat dari onMs". Ini fungsi dari sketch di atas. Ia tidak pernah melihat onMs itu sendiri, hanya tempat tinggalnya, dan *value = *value / 2; membaca isinya lalu menulis kembali setengahnya.

Tanpa pointer, sebuah fungsi mendapat salinan angkanya dan variabel milik pemanggil tetap seperti semula. Itulah seluruh alasan memberikan sebuah alamat.

firmware/uno/examples/cppptr (fungsi yang berjalan di atas)
static void halve(int *value) {
  *value = *value / 2;
}

Fungsi yang mengubah dua variabel

Menukar dua angka adalah ujian klasiknya. swap(&x, &y) di bawah mencetak "8 3", jadi kedua variabel pemanggilnya berubah. Reference C++ melakukan tugas yang sama dengan tanda baca yang lebih sedikit: int &a di daftar parameter, dan tanpa & atau * di tempat lain. swapRef(x, y) menukarnya kembali dan mencetak "3 8".

Library Arduino memakai keduanya. Reference tidak bisa kosong dan tidak bisa dipindah untuk menunjuk ke tempat lain; pointer bisa bernilai nullptr, yang bisa diuji oleh sebuah fungsi, dan bisa menelusuri sebuah array.

Menukar, dengan pointer dan dengan reference
void swap(int *a, int *b) {
  int keep = *a;
  *a = *b;
  *b = keep;
}

void swapRef(int &a, int &b) {
  int keep = a;
  a = b;
  b = keep;
}

void setup() {
  Serial.begin(9600);
  int x = 3, y = 8;
  swap(&x, &y);
  Serial.print(x);
  Serial.print(" ");
  Serial.println(y);
  swapRef(x, y);
  Serial.print(x);
  Serial.print(" ");
  Serial.println(y);
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Array datang sebagai pointer

An array handed to a function is handed over as a pointer to its first element. So in the sketch below, sizeof(rates) printed 8, four ints of 2 bytes, but the same sizeof inside show() printed 2: the size of a pointer. Clang warned: sizeof on array function parameter will return size of 'int *' instead of 'int[]'. That is why a function that takes an array also takes its length, as sumOf(rates, RATE_COUNT) does above.

Indexes and pointers are two spellings of one thing. With int *p = rates;, both *(p + 3) and p[3] printed 800. p++ moves the pointer on by one int, 2 bytes, so *p then printed 200.

sizeof di luar dan di dalam fungsi
int rates[] = {100, 200, 400, 800};

void show(int list[]) {
  Serial.println(sizeof(list));
}

void setup() {
  Serial.begin(9600);
  Serial.println(sizeof(rates));
  show(rates);
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Menelusuri string, dan daftar fungsi

A string in quotes is a row of characters with a zero byte at the end, and const char *message = "Mokxi"; points at its first letter. A loop that moves the pointer until it reaches the zero printed "M o k x i". That is how strlen() and Serial.print() find the end of your text.

Pointer juga bisa menyimpan alamat sebuah fungsi. Sketch di bawah menyimpan tiga fungsi dalam sebuah array dan memanggilnya bergantian; ia mencetak "slow", "fast" dan "off". Menu atau kumpulan pola lampu yang dipilih lewat tekanan tombol adalah penggunaan yang lazim: tombol mengubah sebuah angka, dan modes[number]() menjalankan mode itu.

Array dari fungsi
void slow() {
  Serial.println("slow");
}

void fast() {
  Serial.println("fast");
}

void off() {
  Serial.println("off");
}

void (*modes[])() = {slow, fast, off};

void setup() {
  Serial.begin(9600);
  for (int i = 0; i < 3; i++) {
    modes[i]();
  }
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Kesalahan, dibuat dengan sengaja

Angka di tempat alamat: int *p = x; menghentikan build dengan cannot initialize a variable of type 'int *' with an lvalue of type 'int'. GCC bilang invalid conversion from 'int' to 'int*'. Tulislah &x.

Alamat yang sudah hilang: fungsi yang mengembalikan pointer ke array lokalnya sendiri menyerahkan memori yang langsung dipakai ulang begitu ia kembali. Clang memperingatkan address of stack memory associated with local variable 'text' returned, dan sketch itu mencetak baris kosong alih-alih "ready". GCC bilang address of local variable 'text' returned. Jadikan array itu static, atau suruh pemanggilnya memberikan buffer untuk diisi.

Alamat dari ketiadaan: pointer yang diisi nullptr tidak menunjuk apa pun. Ujilah if (p == nullptr) sebelum memakai pointer yang mungkin belum diisi; sketch itu mencetak "points at nothing".

Buka rangkaian ini di editor. Arduino Uno: dua lampu, dan delay yang dibagi dua lewat pointer, disambungkan seperti yang dijalankan di bagian atas halaman ini. Ubah komponen atau nilainya dan jalankan lagi.

Pertanyaan

Apa itu pointer di Arduino?

Variabel yang menyimpan alamat memori variabel lain, bukan sebuah nilai. Di Uno ukurannya 2 byte. *p membaca atau menulis apa pun yang ada di alamat itu.

Apa bedanya * dan & dalam kode Arduino?

& sebelum variabel memberikan alamatnya. * dalam deklarasi membuat pointer, dan * sebelum pointer di tempat lain menuju nilai yang ditunjuknya. Dalam daftar parameter, & setelah tipe membuat reference.

Harus pakai pointer atau reference?

Pakai reference saat sebuah fungsi harus mengubah satu variabel yang selalu dimiliki pemanggilnya. Pakai pointer saat mungkin tidak ada yang bisa ditunjuk, atau untuk menelusuri sebuah array.

Kenapa sizeof salah di dalam fungsi saya?

Array datang sebagai pointer, jadi sizeof memberikan ukuran pointer, 2 byte di Uno. Kirim panjangnya sebagai parameter kedua, dihitung dengan sizeof di tempat array dideklarasikan.

Apakah aku perlu pointer untuk memprogram Arduino?

Tidak untuk awal. Kamu memakainya tanpa sadar setiap kali mengirim array atau string ke sebuah fungsi, dan kamu memerlukannya untuk menulis fungsi yang mengubah variabel pemanggilnya atau untuk menyimpan daftar fungsi.

Rakit versi nyatanya

Buka editor, ubah sebuah nilai, dan lihat angkanya ikut berubah. Tidak ada yang perlu dipasang, dan tidak perlu akun.