Belajar

Arduino delayMicroseconds(): jeda singkat, terukur

Pemula

Atau lihat semua pelajaran.

  • 526komponen di meja kerja
  • 46board sedang berjalan
  • 1.00xwaktu nyata, di semua board
Arduino Uno: servo yang digerakkan pulsa berwaktu mikrodetiklive0.000 s 0.00x
Klik untuk membukanya di editor
Slider mengatur sudutnya; setiap pulsa ke servo dihitung waktunya dengan delayMicroseconds().

delayMicroseconds(us) menunggu selama jumlah itu sepersejuta detik, lalu lanjut. Pakai untuk jeda singkat dan tepat yang terlalu kasar untuk delay(): pulsa trigger 10 µs sensor ultrasonik, pulsa 1 sampai 2 ms untuk servo, pulsa langkah driver stepper. Untuk apa pun di atas sekitar 16 milidetik, pakai delay(): pada Uno, delayMicroseconds() tidak bisa menghitung setinggi itu.

Rangkaian di atas adalah fader servo. Tekan Jalankan dan geser slider-nya. Servo mengikuti, dan serial monitor mencetak tiap sudut, misalnya "fader 1000 -> 175 degrees". Kode servo di bawahnya membuat tiap pulsa dengan delayMicroseconds(): 544 µs untuk 0 derajat, 2400 µs untuk 180, lima puluh kali per detik.

Di bawah ini berapa lama ia benar-benar menunggu, batasnya dan apa yang terjadi melewatinya, pulsa servo buatan tangan, dan kesalahan yang sering dilakukan orang, masing-masing dijalankan di Uno dengan micros() menghitung waktunya.

delay() atau delayMicroseconds()

delay() menghitung dalam milidetik dan delayMicroseconds() dalam mikrodetik, seribu kali lebih kecil. delay(1) dan delayMicroseconds(1000) sama-sama satu milidetik: diukur dengan micros(), delay(1) memakan 1020 µs dan delayMicroseconds(1000) memakan 1016 µs, milidetik yang sama dalam satu langkah micros(). Keduanya menghentikan sketch selama menunggu, jadi bukan cara melakukan dua hal sekaligus. Itu tugas millis().

micros() sendiri menghitung dalam langkah 4 µs pada Uno 16 MHz, jadi setiap waktu di bawah adalah kelipatan 4. Itu juga langkah terhalus yang bisa diukur dengannya: untuk mengukur yang lebih singkat, jalankan seribu kali lalu bagi, seperti jeda singkat di bawah ini.

Berapa lama ia benar-benar menunggu

Sketch ini mengukur tujuh jeda dengan micros(). Ia mencetak "10 us took 16", "100 us took 104", "1000 us took 1016" dan "10000 us took 10140". Beberapa mikrodetik ekstra adalah pemanggilan itu sendiri dan micros(). Jeda yang lebih panjang hasilnya 1 sampai 2 persen lebih lama karena interrupt timer yang menjalankan millis() aktif tiap 1024 µs dan jeda tidak berhenti untuknya.

Lalu batasnya. "16383 us took 16608", dan 16384 memakan 16612. 20000 memakan 3668. Itu bukan salah ketik: delayMicroseconds() pada Uno menghitung dalam angka 16-bit seperempat mikrodetik, jadi apa pun di atas 16383 berputar balik. 20000 berarti 3616 melewati batas, jadi ia menunggu sekitar 3,6 ms.

Ukur tujuh jeda
void setup() {
  Serial.begin(9600);
  unsigned int waits[] = {10, 100, 1000, 10000, 16383, 16384, 20000};
  for (int i = 0; i < 7; i++) {
    unsigned long start = micros();
    delayMicroseconds(waits[i]);
    unsigned long took = micros() - start;
    Serial.print(waits[i]);
    Serial.print(" us took ");
    Serial.println(took);
  }
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Jeda sangat singkat

Di bawah sekitar 3 µs pemanggilan itu sendiri lebih lama dari jedanya. Sketch ini menjalankan tiap nilai seribu kali. 0 memakan total 1376 µs, 1 memakan 1380 dan 2 memakan 1388, lalu 3 memakan 3408, 4 memakan 4432 dan 5 memakan 5444. Jadi 1 dan 2 tidak menunggu lebih lama dari 0 (beberapa mikrodetik di antara ketiganya adalah tempat interrupt timer jatuh), dan dari 3 ke atas tiap pemanggilan adalah nilai itu plus sekitar 0,4 µs.

Core Uno milik Mokxi langsung kembali untuk 0, 1 dan 2, karena pemanggilan saja sudah memakan kira-kira selama itu; core Arduino melakukan hal yang sama untuk 0 dan 1. Kalau kamu butuh pulsa lebih singkat dari beberapa mikrodetik, tulis register port langsung daripada memanggil digitalWrite() dan delayMicroseconds().

Seribu jeda singkat
void setup() {
  Serial.begin(9600);
  for (int us = 0; us <= 5; us++) {
    unsigned long start = micros();
    for (int i = 0; i < 1000; i++) {
      delayMicroseconds(us);
    }
    Serial.print(us);
    Serial.print(": ");
    Serial.println(micros() - start);
  }
}

void loop() {
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Pulsa servo buatan tangan

Servo membaca lebar pulsa, dikirim sekitar 50 kali per detik: sekitar 544 µs untuk 0 derajat dan 2400 µs untuk 180. Sketch ini membuat pulsanya sendiri, tanpa library. Dengan 1500 servo pergi ke 94,0 derajat. Dengan 1000 ia pergi ke 45,5 dan dengan 2400 ke 180.

1472 µs adalah titik tengah persisnya, dan itu menempatkan servo di 91,3 derajat, bukan 90. Derajat ekstra itu datang dari digitalWrite(): tiap pemanggilan memakan beberapa mikrodetik, jadi pulsa keluar sekitar 12 µs lebih lebar dari angka yang kamu tulis. Library Servo sudah mengatasinya, itu salah satu alasan memakainya.

Pulsa servo tanpa library
const int SERVO = 9;

void setup() {
  pinMode(SERVO, OUTPUT);
}

void loop() {
  digitalWrite(SERVO, HIGH);
  delayMicroseconds(1500);  // the pulse: 1.5 ms is about the middle
  digitalWrite(SERVO, LOW);
  delay(20);                // the gap: about 50 pulses a second
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Gelombang kotak, dan kenapa hasilnya lambat

Dua jeda 50 µs seharusnya menghasilkan gelombang kotak 10 kHz. Penghitung frekuensi di pin 9 membaca 8732 Hz. Sketch yang sama dengan jeda 500 µs membaca 980 Hz, bukan 1000. Selisihnya adalah beberapa mikrodetik digitalWrite() dan loop() yang sama pada tiap setengah gelombang, yang makin berarti makin singkat jedanya.

Untuk frekuensi yang stabil, biarkan hardware yang mengerjakannya: tone() untuk suara dan analogWrite() untuk PWM berjalan pada timer dan tidak bergeser karena kodemu.

Gelombang kotak di pin 9
const int OUT = 9;

void setup() {
  pinMode(OUT, OUTPUT);
}

void loop() {
  digitalWrite(OUT, HIGH);
  delayMicroseconds(50);
  digitalWrite(OUT, LOW);
  delayMicroseconds(50);
}

Buka sketch ini di editorKodenya saja: editor menempatkan board dan komponen yang bisa dibacanya dari sketch.

Kesalahan umum

Memberi nilai lebih dari 16383. delayMicroseconds(20000) di sini menunggu 3668 µs. Untuk jeda 20 ms antar pulsa servo, pakai delay(20); dengan delayMicroseconds(20000) sketch servo di atas mengirim 194 pulsa per detik, bukan 46.

Memakainya untuk mengukur waktu yang lama. Loop dari seribu pemanggilan delayMicroseconds(10) memakan 10388 µs, bukan 10000. Error menumpuk; pakai micros() untuk memeriksa waktu daripada menambah jeda.

Mengira 1 µs adalah 1 µs. Pemanggilannya sendiri lebih lama dari itu.

Memakainya untuk melakukan dua hal sekaligus. Seperti delay(), ia memblokir. Pakai millis() atau micros() dan periksa waktunya.

Buka rangkaian ini di editor. Arduino Uno: servo yang digerakkan pulsa berwaktu mikrodetik, dirangkai seperti saat berjalan di bagian atas halaman ini. Ubah satu komponen atau nilainya lalu jalankan lagi.

Buka rangkaian ini

Pertanyaan

Berapa nilai maksimum untuk delayMicroseconds?

16383 pada Uno 16 MHz. Nilai lebih besar akan berputar kembali: delayMicroseconds(20000) di sini hanya menunggu sekitar 3.6 ms. Gunakan delay() untuk waktu lebih dari sekitar 16 ms.

Apa bedanya delay dengan delayMicroseconds?

delay() menunggu dalam milidetik dan delayMicroseconds() dalam mikrodetik, seribu kali lebih singkat. delay(1) dan delayMicroseconds(1000) keduanya menunggu sekitar satu milidetik. Keduanya memblokir sketch selama menunggu.

Seberapa akurat delayMicroseconds?

Dalam beberapa mikrodetik untuk waktu singkat: 100 di sini memakan 104 µs. Waktu lebih lama jadi 1 sampai 2 persen lebih panjang karena interupsi timer millis() tetap berjalan, dan waktu 1 dan 2 µs tidak lebih lama dari 0.

Apakah delayMicroseconds memblokir kode lain?

Ya. Tidak ada kode lain di loop() yang berjalan sampai ia selesai, sama seperti delay(). Interupsi tetap berjalan, itulah sebabnya waktu lama jadi sedikit lebih panjang.

Rakit versi nyatanya

Buka editor, ubah sebuah nilai, dan lihat angkanya ikut berubah. Tidak ada yang perlu dipasang, dan tidak perlu akun.