Aprender

Indicador de nivel de batería para Arduino

Principiante

O mira todas las lecciones.

  • 526componentes en el banco de trabajo
  • 46placas funcionando ahora
  • 1.00xtiempo real, en todas las placas
Arduino Uno: un indicador de nivel de batería 18650en vivo0.000 s 0.00x
Haz clic para abrirlo en el editor
Una celda 18650 en A0, su voltaje y porcentaje en una LCD I2C, y un semáforo para el nivel. Presiona Ejecutar y luego arrastra el control deslizante de carga en la batería.

Un indicador de nivel de batería es un analogRead y un poco de aritmética. El circuito de arriba es un Arduino Uno leyendo una celda de litio-ion 18650 en A0, con el voltaje y la carga en porcentaje en una LCD I2C 16x2 y un módulo de semáforo para el nivel: verde por encima del 50 %, amarillo de 20 a 50 %, y un rojo parpadeante por debajo del 20 %.

Presiona Ejecutar y luego arrastra el control deslizante de carga en la batería. Llena, el monitor serie imprime 4.20 V y 100 %. Con media carga imprime 3.60 V y 50 % y la luz se vuelve amarilla. Al 10 % imprime 3.12 V y la luz roja parpadea, y vacía está en 3.00 V y 0 %.

Lo que necesitas

  • Un Arduino Uno
  • Una celda de litio-ion 18650 en un portapilas
  • Una LCD 16x2 con un módulo I2C
  • Un módulo de LEDs semáforo, o tres LEDs con resistencias de 220 ohm
  • Cables puente y una protoboard para los rieles de alimentación

Cableado

Componente y pinVa aNota
+ de la batería (cable rojo)A0Directo: 4.2 V está por debajo de la referencia de 5 V del Uno
- de la batería (cable negro)GNDLa celda y el Uno deben compartir tierra
Semáforo G, Y, RPines 2, 3, 4GND a GND
SDA y SCL de la LCDA4, A5VCC a 5V, GND a GND; dirección 0x27

Por qué una 18650 va directo a A0

analogRead() compara un pin con los 5 V del Uno y cuenta de 0 a 1023. Una celda de ion de litio tiene 4.2 V cuando está llena y unos 3.0 V cuando está vacía, siempre por debajo de 5 V, así que puede ir directo a un pin analógico sin divisor. Su terminal negativo debe ir al GND del Uno, o el pin no tendrá nada contra qué medir.

Los voltios son el conteo por 5 / 1023. El sketch primero promedia 16 lecturas, lo que estabiliza el último dígito en una placa real, donde la lectura varía en uno o dos conteos.

De voltios a porcentaje

El sketch convierte 3.0 V en 0 % y 4.2 V en 100 % en línea recta y lo limita de 0 a 100. Después elige la luz e imprime ambos valores en la LCD y en el monitor serie cada medio segundo.

El sketch que ejecuta el circuito
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

const int BATTERY_PIN = A0;
const int GREEN_PIN = 2;
const int YELLOW_PIN = 3;
const int RED_PIN = 4;

const float EMPTY_V = 3.0;
const float FULL_V = 4.2;

LiquidCrystal_I2C lcd(0x27, 16, 2);
bool blink = false;

void setup() {
  pinMode(GREEN_PIN, OUTPUT);
  pinMode(YELLOW_PIN, OUTPUT);
  pinMode(RED_PIN, OUTPUT);
  Serial.begin(9600);
  Serial.println("Battery level indicator");
  lcd.init();
  lcd.backlight();
  lcd.print("18650 battery");
}

void loop() {
  // Average 16 readings to steady the last digit.
  long sum = 0;
  for (int i = 0; i < 16; i++) sum += analogRead(BATTERY_PIN);
  float volts = sum / 16.0 * 5.0 / 1023.0;

  int percent = (int)((volts - EMPTY_V) / (FULL_V - EMPTY_V) * 100.0 + 0.5);
  percent = constrain(percent, 0, 100);

  blink = !blink;
  digitalWrite(GREEN_PIN, percent > 50 ? HIGH : LOW);
  digitalWrite(YELLOW_PIN, percent >= 20 && percent <= 50 ? HIGH : LOW);
  digitalWrite(RED_PIN, percent < 20 && blink ? HIGH : LOW);

  lcd.setCursor(0, 1);
  lcd.print(volts, 2);
  lcd.print(" V  ");
  lcd.print(percent);
  lcd.print(" %    ");

  Serial.print(volts, 2);
  Serial.print(" V  ");
  Serial.print(percent);
  Serial.println(" %");
  delay(500);
}

Abrir este sketch en el editorSolo el código: el editor coloca la placa y los componentes que puede leer del sketch.

Una batería de más de 5 V necesita un divisor

Two 18650s in series are 8.4 V full, a 9 V battery is 9.6 V fresh, and a 12 V lead-acid battery is 12.8 V. Any of them straight on A0 is over the pin’s limit. Put two resistors in series from the battery’s plus to GND and read the point between them. With two equal 10 k resistors, 8.4 V reads as 4.2 V; with 10 k on top and 4.7 k below, 12 V reads as 3.84 V. Multiply the reading back up in the sketch by the same ratio, and keep to resistors of about 10 k: the divider then drains under a milliamp, and its output stays inside the 10 k source the ATmega328P’s ADC is designed for.

Después cambia los puntos de batería vacía y llena a los de la propia batería: 6.0 V y 8.4 V para dos celdas de ion de litio, o 11.8 V y 12.8 V en reposo para una batería de plomo-ácido. La guía del LM2596 lee un adaptador de 12 V a través de ese divisor de 10 k y 4.7 k, en un circuito en funcionamiento.

Por qué el porcentaje es solo una guía

Una celda de ion de litio real no baja en línea recta. Su voltaje es plano en la parte media y cae rápido en ambos extremos, así que un medidor de línea recta marca un poco bajo cuando la celda está llena y cae rápido cuando está por descargarse. El voltaje también baja bajo carga: mídelo mientras corre un motor y la celda parecerá más descargada de lo que está. Los chips medidores de batería cuentan en su lugar la corriente que entra y sale.

La batería de Mokxi se mueve en línea recta entre sus puntos de vacía y llena mientras arrastras la carga, así que las lecturas aquí siguen el control deslizante con exactitud. No se descarga sola mientras el circuito corre, así que el control de carga es la forma de probar la advertencia de batería baja.

Alimentar el Arduino con la misma batería

En un Uno real el pin 5V quiere 5 V estables, y VIN o el conector de barril quieren de 7 a 12 V para el regulador de la placa. Una sola 18650 no es ninguna de las dos, así que una celda individual necesita un convertidor elevador hasta 5 V. Dos celdas en serie, de 6 a 8.4 V, quedan en el límite inferior de lo que VIN acepta, así que muchos proyectos usan un convertidor reductor a 5 V. Una vez que el Uno se alimenta desde la batería, su propia referencia de 5 V puede moverse con ella, así que mide la batería contra la referencia interna o mediante un divisor alimentado desde una fuente regulada.

En Mokxi el Uno siempre se alimenta desde su USB e ignora VIN, así que el circuito de aquí muestra la mitad de medición. La sección de baterías tiene todos los tipos comunes, desde paquetes de AA y celdas de moneda hasta bolsas LiPo, paquetes RC 2S y 3S y un bloque de plomo-ácido de 12 V.

Abre este circuito en el editor. Arduino Uno: un indicador de nivel de batería 18650, cableado tal como corre en la parte superior de esta página. Cambia un componente o un valor y ejecútalo de nuevo.

Abrir el circuito

Preguntas

¿Puedo conectar una batería directo a un pin analógico del Arduino?

Solo si su voltaje se mantiene por debajo de la referencia de la placa, 5 V en un Uno. Una celda de ion de litio, de 3.0 a 4.2 V, está bien. Cualquier cosa mayor necesita un divisor de voltaje antes del pin, y el negativo de la batería debe ir a GND.

¿Qué voltaje tiene una 18650 llena y una vacía?

Unos 4.2 V llena y 3.0 V vacía en reposo. Bajo una carga pesada, la hoja de datos de una celda permite que baje a 2.5 V, y se recupera a unos 3.0 V cuando la carga se detiene.

¿Cómo mido una batería de 12 V con un Arduino?

Con un divisor, por ejemplo 10 k del positivo de la batería a A0 y 4.7 k de A0 a GND, que convierte 12 V en 3.84 V. Multiplica la lectura por 14.7 / 4.7 en el sketch.

¿Qué tan precisa es un porcentaje de batería calculado con el voltaje?

Aproximada. El voltaje de una celda de ion de litio es plano en la mitad de su carga y cae bajo carga, así que un medidor de voltaje sirve para saber si está llena, baja o vacía, no para dar una cifra exacta.

¿Puede Mokxi simular un Arduino funcionando con batería?

Simula baterías que alimentan el resto de un circuito, con su resistencia interna y su carga. El Uno simulado en sí siempre funciona desde USB e ignora VIN.

Ármalo en la vida real

Abre el editor, cambia un valor y mira cómo cambia el número con él. Nada que instalar y sin necesidad de cuenta.