تعلّم

لغة تجميع AVR في المتصفح، على لوحة Arduino Uno محاكاة

مبتدئ

أو تصفّح كل الدروس.

  • 526قطعة على المنضدة
  • 46لوحة تعمل الآن
  • 1.00xزمن حقيقي، على كل لوحة
Arduino Uno: LED على الطرف 13، يرمشمباشر0.000 s 0.00x
اضغط لفتحه في المحرر
برنامج الرمش المدمج، بلغة C، على LED ومقاومة 220 أوم على الطرف 13. افتحه في المحرر واختر الرمش بلغة التجميع لتشغيل LED نفسه من main.S.

لوحة Arduino Uno هي شريحة ATmega328P، وتحت كل كود يعمل كود آلة AVR: 32 مسجّلًا، وبايت للأعلام، وتعليمات يستغرق كل منها عددًا معروفًا من دورات الساعة. يتيح لك Mokxi كتابة هذه الطبقة مباشرة. أضف تبويب .S بجانب كودك، أو اجعل اللوحة كلها مشروع لغة تجميع بلا نواة Arduino أصلًا، ثم اضغط «تشغيل».

يستعرض هذا الصفحة برنامج الرمش الذي يسلّمه لك المحرر: ماذا تفعل كل تعليمة، ولماذا PORTB رقمان مختلفان، وكيف يصبح عدّاد حلقة 250 ميلي ثانية بالضبط. ثم مقاطعة مؤقّت، ومصحح الأخطاء يقرأ التعليمات واحدة تلو الأخرى.

الدائرة أعلاه هي برنامج الرمش المدمج المعتاد، مكتوب بلغة C. لتشغيل نسخة لغة التجميع، افتحها في المحرر، واختر Uno، ثم اختر **الرمش بلغة التجميع** ضمن **لغة التجميع (بلا Arduino)** في لوحة البرنامج الثابت. تصبح ملفات اللوحة ملفًا واحدًا هو main.S.

الرمش بلغة التجميع، سطرًا بسطر

لا شيء مخفي تحت هذا البرنامج: لا setup()، ولا loop()، ولا مقاطعة millis() في الخلفية. كود البدء يصفّر r1، ويضع المكدس في أعلى الذاكرة، ثم يستدعي main. بعد ذلك، كل دورة تصرفها الشريحة هي دورة كتبتها أنت. يعمل #include <avr/io.h> لأن ملف .S يمر أولًا عبر معالج C الأولي، وهو ما يمنحك أسماء المسجّلات والبتات.

تضبط sbi بتًا واحدًا في مسجّل إدخال/إخراج واحد. الأولى تجعل PB5، وهو الطرف المعلّم 13، مخرجًا. والثانية هي الحيلة التي تستحق المعرفة: كتابة 1 في بت من PINB تقلب البت المقابل في PORTB، في تعليمة واحدة من دورتين بلا قراءة وبلا قناع. ثم تستدعي rcall التأخير، ويعود ret، ويكرّر rjmp loop الدورة من جديد.

main.S: قالب الرمش البدئي، كما تسلّمه لك لوحة البرنامج الثابت
; Blink the LED on pin 13 (PB5) every 250 ms, in AVR assembly.
; No Arduino core: the startup code clears r1, puts the stack at RAMEND
; and calls main, as avr-gcc's does.

#include <avr/io.h>

    .section .text
    .global main
main:
    sbi  _SFR_IO_ADDR(DDRB), DDB5     ; PB5 is an output
loop:
    sbi  _SFR_IO_ADDR(PINB), PINB5    ; writing 1 to PINB5 toggles PB5
    rcall delay_250ms
    rjmp loop

; 250 ms at 16 MHz is 4,000,000 cycles: 40 times 100,000.
; The inner loop is 4 cycles a turn (SBIW 2, BRNE 2), 25,000 turns.
delay_250ms:
    ldi  r18, 40
outer:
    ldi  r24, lo8(25000)
    ldi  r25, hi8(25000)
inner:
    sbiw r24, 1
    brne inner
    dec  r18
    brne outer
    ret

المسجّلات، وأيها يمكنك استخدامه

تحتوي الشريحة على 32 مسجّلًا عامًا، من r0 إلى r31، كل واحد بايت واحد، ويُوصل في دورة واحدة. النصف العلوي خاص: ldi، التي تحمّل ثابتًا، تعمل فقط على r16 إلى r31، ولهذا يحتفظ برنامج الرمش بعدّاداته في r18 وr24 وr25. اكتب ldi r3, 5 فيتوقف البناء برسالة ldi works only on r16 to r31, and r3 is not one of them.

Two registers are spoken for: r1 must hold zero, because the C compiler assumes it everywhere, and r0 is the scratch byte. Then there is SREG, eight flags set by the last instruction that did arithmetic. sbiw sets Z when its result reaches zero, and brne is simply "branch if Z is clear". sbi and cbi change no flags at all. The debugger spells sreg out as ITHSVNZC, with a dot for each flag that is clear.

المسجّلات التي يقابلها أول برنامج بلغة التجميع
السجلما هياحذر من
r0البايت المؤقت، `__tmp_reg__`. `lpm` يضع النتيجة هنا افتراضيًا.يستخدمه المترجم، لذا لا تنجو أي قيمة من الاستدعاء.
r1Always zero, `__zero_reg__`.`mul` يكتب في r1:r0، لذا نفّذ `clr r1` بعده.
من r2 إلى r17عامة، لكنها ملك للمستدعي.احفظها واستعدها إذا استخدمتها دالتك.
من r16 إلى r31النصف العلوي.`ldi` و`cpi` و`subi` و`andi` و`ori` تعمل هنا فقط.
r18 إلى r27، وr30 وr31حرة داخل دالتك.دالة C تستدعيها قد تكتب فوقها.
r24, r26, r28, r30الأزواج التي تعمل عليها `adiw` و`sbiw`.r24:r25 يحمل أيضًا وسيطة ونتيجة بحجم 16 بت.
X, Y, Zr26:r27 وr28:r29 وr30:r31: المؤشرات.Z وحده يقرأ ذاكرة flash، عبر `lpm`. وY هو مؤشر إطار C.
SREGالأعلام: I T H S V N Z C.تضبطها العمليات الحسابية والمقارنات، لا `sbi` ولا `ldi` ولا `mov`.

عناوين الإدخال/الإخراج وعناوين البيانات: لماذا PORTB يساوي 0x25 و0x05

This is the one that costs people an evening. In a .S file, #include <avr/io.h> defines PORTB as its data address, 0x25, which is what lds and sts want. The short instructions, in, out, sbi, cbi, sbic and sbis, want the I/O address instead, which is 32 lower: 0x05. So you wrap the name in _SFR_IO_ADDR().

إذا أخطأت يوقف Mokxi البناء قبل تشغيل أي أداة، لأن الخطأ وإلا سيتحوّل إلى برنامج يكتب في المسجّل الخطأ. sbi PORTB, 5 يعطي PORTB is the data address 0x25 here, and sbi takes its I/O address: write _SFR_IO_ADDR(PORTB), which is 0x05. المسجّلات فوق عنوان الإدخال/الإخراج 63، مثل TCCR1B، لا شكل قصير لها إطلاقًا: استخدم lds وsts.

البت نفسه، بثلاث طرق
; As avr-libc defines them: a name is a data address.
    sbi  _SFR_IO_ADDR(DDRB), DDB5   ; I/O 0x05, bit 5
    lds  r16, PORTB                 ; data 0x25
    sts  PORTB, r16

; Or move every name down to its I/O address, once:
#define __SFR_OFFSET 0
#include <avr/io.h>
    sbi  DDRB, DDB5                 ; now this is right

عدّ الدورات: 4,000,000 منها لأجل 250 ms

لا توجد delay() هنا، لذا التأخير حلقة تعدّها يدويًا. تعمل Uno بتردد 16 MHz، فالدورة الواحدة 62.5 نانو ثانية، و250 ميلي ثانية هي 4,000,000 دورة. الحلقة الداخلية للرمش تعليمتان: sbiw r24, 1 تستغرق دورتين، وbrne inner تستغرق دورتين عند القفز. الدورة الواحدة أربع دورات، و25,000 دورة هي 100,000 دورة ساعة، و40 تكرارًا لذلك يعطي الـ 4,000,000. تضيف الحلقة الخارجية نحو 120 دورة في المجموع، أي ثلاثة أجزاء من مئة ألف.

The simulator spends the cycles the data sheet gives each instruction, so you can prove this from a sketch. Set Timer 1 to the full clock, so it counts once per CPU cycle, read it, run a known loop, read it again. Fifty turns of nop, dec and brne is 50 times 4 less the one the last brne saves by falling through, which is 199, plus 2 for the lds and 1 for the ldi. It prints 202, every time.

النسخة الطويلة تتفق: 160 تكرارًا لحلقة من 25,000 دورة هي 16,000,000 دورة ساعة، وmicros() يضعها بين 1,000,000 و1,015,000 ميكرو ثانية. النصف بالمئة الزائدة هي مقاطعة المؤقّت 0 نفسه، التي تُبقي millis() يعمل، وUno حقيقية تخسرها أيضًا.

ما تكلفه تعليمات الرمش على ATmega328P، بدورات الساعة
التعليمةالدوراتفي الرمش
`ldi`1يحمّل عدّادي الحلقتين.
`sbi`, `cbi`2يجعل PB5 مخرجًا، ثم يقلبه.
`sbiw`2ينقص 1 من العدّاد ذي 16 بت في r24:r25.
`dec`1ينقص 1 من العدّاد الخارجي في r18.
`brne`2 عند القفز، 1 عند عدم القفزيغلق الحلقتين: اثنان زائد اثنان يجعلان الدورة أربع نبضات.
`rjmp`2يعود إلى أعلى الحلقة الرئيسية.
`rcall`3ينادي دالة التأخير.
`ret`4يعود منها.
sketch.ino: قياس زمن حلقة مقابل Timer 1، والذي يطبع 202
void setup() {
  Serial.begin(9600);
  TCCR1A = 0;
  TCCR1B = _BV(CS10);  // clk/1: one count per CPU cycle
  uint8_t start, stop, n;
  noInterrupts();
  asm volatile(
    "lds %[start], %[tcnt]\n\t"
    "ldi %[n], 50\n"
    "1:\n\t"
    "nop\n\t"
    "dec %[n]\n\t"
    "brne 1b\n\t"
    "lds %[stop], %[tcnt]\n\t"
    : [start] "=&r"(start), [stop] "=&r"(stop), [n] "=&d"(n)
    : [tcnt] "i"(&TCNT1L));
  interrupts();
  Serial.println((uint8_t)(stop - start));  // 202
}

void loop() {}

افتح هذا الكود في المحررالكود وحده: يضع المحرر اللوحة والقطع التي يستطيع قراءتها من الكود.

مقاطعة مؤقّت بدلًا من حلقة تأخير

الحلقة المعدودة طريقة جيدة لتعلّم النبضات وطريقة سيئة لقياس الوقت، لأن المعالج لا يستطيع فعل شيء آخر أثناء العد. في الأسفل، يعمل Timer 1 بوضع CTC على الساعة مقسومة على 256، فيعدّ 62,500 مرة في الثانية، فتتحقق قيمة المقارنة 31,249 كل نصف ثانية. OCIE1A في TIMSK1 يطلب المقاطعة، وsei يسمح بحدوث المقاطعات أصلًا.

TIMER1_COMPA_vect اسم من avr/io.h، وهو في الحقيقة __vector_11، المدخل الحادي عشر من جدول المتجهات. أعلنه .global، وعرّف التسمية، فيقفز إليه جدول كود الإقلاع. كل متجه بلا معالِج منك يحصل على reti ضعيف، فتعود أي مقاطعة شاردة بهدوء. اختم بـ reti، لا بـ ret. يتّسع هذا المعالِج في ثلاثة أسطر فقط لأن sbi لا يغيّر أي راية.

main.S: قالب البداية بمقاطعة المؤقّت
; Timer 1 interrupts twice a second and the handler toggles pin 13 (PB5).
; main only sets the timer up; the LED is all the interrupt's work.

#include <avr/io.h>

    .section .text
    .global main
main:
    sbi  _SFR_IO_ADDR(DDRB), DDB5
    ; CTC mode, clock / 256: 16 MHz / 256 = 62,500 counts a second,
    ; so a compare at 31,249 is every 0.5 s.
    ldi  r16, hi8(31249)
    sts  OCR1AH, r16                  ; high byte first
    ldi  r16, lo8(31249)
    sts  OCR1AL, r16
    clr  r16
    sts  TCCR1A, r16
    ldi  r16, (1 << WGM12) | (1 << CS12)
    sts  TCCR1B, r16
    ldi  r16, (1 << OCIE1A)           ; interrupt on compare match A
    sts  TIMSK1, r16
    sei
idle:
    rjmp idle

; TIMER1_COMPA_vect is __vector_11; the vector table jumps here.
    .global TIMER1_COMPA_vect
TIMER1_COMPA_vect:
    sbi  _SFR_IO_ADDR(PINB), PINB5    ; toggle the LED (SBI changes no flags)
    reti

نداء لغة التجميع من كود

لست مضطرًا للتخلي عن نواة Arduino. أبقِ sketch.ino، وأضف تبويبًا اسمه blink.S، فيُترجم الاثنان ويُربطان معًا، تمامًا كما يبني Arduino IDE ملف .S بجانب الكود. Serial وmillis() وpinMode() تستمر في العمل.

The join is extern "C", which stops C++ from mangling the name, and the AVR calling convention, which decides where the values are. Arguments arrive in r24, then r22, then r20; a result goes back in r24, or r25:r24 when it is two bytes. r1 must be zero again on return, and r2 to r17, r28 and r29 belong to the caller. It works in both directions: here the sketch calls led_toggle, and led_toggle calls bump, an ordinary C function back in the sketch.

blink.S: تبويب يناديه الكود، وينادي الكود بدوره
#include <avr/io.h>

; void led_toggle(void): toggle pin 13, then count it in C.
    .global led_toggle
led_toggle:
    sbi  _SFR_IO_ADDR(PINB), PINB5
    call bump                 ; a C function of the sketch
    ret

الكود الذي بجانبه

شغّله مع LED ومقاومة 220 أوم على الطرف 13: تطبع الشاشة التسلسلية 1، 2، 3، 4، 5 بينما يتبدّل الـ LED كل 250 ملّي ثانية. هذه نواة Arduino مع دالة واحدة مكتوبة بلغة التجميع. لعدّة تعليمات قليلة، asm volatile المضمّن مع القيود أقل مراسيم، كما في كود عدّ النبضات أعلاه.

sketch.ino: النصف الآخر
extern "C" void led_toggle(void);
extern "C" volatile int bumps;
volatile int bumps = 0;
extern "C" void bump(void) { bumps++; }

void setup() {
  Serial.begin(9600);
  pinMode(13, OUTPUT);
}

void loop() {
  led_toggle();
  Serial.println(bumps);
  delay(250);
}

افتح هذا الكود في المحررالكود وحده: يضع المحرر اللوحة والقطع التي يستطيع قراءتها من الكود.

مشاهدته في مصحح الأخطاء

هنا تتفوق لغة التجميع في محاكي على لغة التجميع على المنضدة. اضغط على الهامش بجانب سطر من تبويب .S فتوضع هناك نقطة توقف، تمامًا كما على سطر C، لأن أرقام الأسطر التي يسجلها البناء هي أسطر التبويب نفسه. اضغط «تشغيل» فتتوقف اللوحة عليه، مع الدائرة كلها.

يُظهر تبويب التنقيح أين توقف، وسجلات النواة نفسها مع sreg مفصّلًا كراياته، وقائمة مراقبة للمتغيرات العامة، وفك التجميع: التعليمات المحيطة بعدّاد البرنامج، وكل صف عنوان، والبايتات، والتعليمة، وسطر المصدر الذي جاءت منه. أوقف التنفيذ على سطر sbi في التبويب أعلاه فيقرأ الصف sbi 0x3, 0x5، وهو ما قصده _SFR_IO_ADDR(PINB), PINB5 فعلًا. «تنفيذ تعليمة» ينفذ تعليمة واحدة بالضبط ويعيد رسم القائمة.

حين لا تتم عملية التجميع، وما الذي يعمل أيضًا

تقع الأخطاء على التبويب والسطر الصحيحين مع جملة تحتها. تعليمة مكتوبة خطأً تقول "lid" is not an AVR instruction وتذكّرك بأن التسمية تنتهي بنقطتين. أما add r16, 5 فهي الخادعة: مترجم LLVM يقرؤها add r16, r5، لذا يتوقف Mokxi بدلًا من ذلك برسالة add takes two registers, and 5 is a constant ويشير إلى subi r16, -5، لأن AVR ليس فيها ADDI.

لغة التجميع هنا ليست حكرًا على AVR. تبويب .S أو .s يعمل على كل لوحة تتم ترجمتها، وPico وSTM32F411 Black Pill لديهما القوالب الأربعة نفسها بصيغة ARM Thumb، حيث يكون ملفك هو البرنامج كله، مع جدول المتجهات وكل شيء. الـ Nano وPro Mini ذات 16 MHz هما الشريحة نفسها الموجودة في Uno. مقالة كتابة لغة التجميع في مركز المساعدة، المذكورة برابط أدناه، هي المرجع للباقي.

افتح هذه الدائرة في المحرر. Arduino Uno: LED على الطرف 13 يومض، موصّلة كما تعمل أعلى هذه الصفحة. غيّر قطعة أو قيمة وشغّلها مرة أخرى.

افتح الدائرة

الأسئلة

هل يمكنني فعلًا كتابة لغة التجميع لـ Arduino في المتصفح؟

نعم. أضف تبويبًا ينتهي بـ .S أو .s فيُجمَّع ويُربط مع كودك، بالطريقة نفسها التي يبني بها Arduino IDE ملفًا كهذا. أو اختر قالب بداية تحت "Assembly (no Arduino)" في لوحة البرنامج الثابت للوحة فتصبح اللوحة كلها main.S واحدًا بلا نواة Arduino تحته.

ما الفرق بين ملف .S وملف .s؟

الحرف الكبير .S يمر أولًا عبر المعالج التمهيدي لـ C، فتعمل فيه #include <avr/io.h> و#define. أما الصغير .s فيُسلَّم إلى المُجمِّع كما هو مكتوب.

لماذا تفشل sbi PORTB, 5 رغم أن PORTB هو السجل الصحيح؟

في ملف .S يكون اسم PORTB عنوانه في الذاكرة، 0x25، كما في avr-libc، بينما sbi يريد عنوان I/O، وهو 0x05. اكتب _SFR_IO_ADDR(PORTB)، أو ضع #define __SFR_OFFSET 0 فوق التضمين.

هل أعداد النبضات هي نفسها كما على شريحة حقيقية؟

نعم، بالنسبة للتعليمات. يصرف الـ ATmega328P المُحاكى النبضات التي يعطيها ورق البيانات لكل تعليمة، فتحسب 50 دورة من nop وdec وbrne بقيمة 202 على Timer 1 بالساعة الكاملة.

هل يمكنني تنفيذ لغة التجميع تعليمة واحدة في كل مرة؟

نعم. نقاط التوقف تعمل على أسطر تبويب .S، ويعرض تبويب التنقيح التعليمات المحيطة بالتوقف مع سطر المصدر الذي جاءت منه كل واحدة. «تنفيذ تعليمة» ينفذ واحدة منها بالضبط.

ابنِ هذا على أرض الواقع

افتح المحرر وغيّر قيمة وشاهد الرقم يتحرك معها. لا شيء لتثبّته ولا حاجة إلى حساب.